Макрос проверки ошибок

[Iskin]

Доброго дня всем! У меня следующая задача.
Надо что бы перед запуском основного макроса, производилась проверка листа на наличие следующих ошибок:
- н/д, знач! и прочее.
- а так же проверка по колонке (в моем случае М:М) на отсутствие данных. Т.е. данные листа должны находится в пределах А1:L 6..... а колонка М должна быть пуста.
При обнаружении ошибок, проверочный макрос должен выводить сообщение типа "обнаружена ошибка" и при нажатии кнопки желательно что бы макрос активировал первую ячейку с ошибкой.

[EducatedFool]

Sub ВыделяемЯчейкиСОшибками()
On Error Resume Next
    Dim sh As Worksheet, cell As Range, ErrRa As Range: Set sh = ActiveSheet
    For Each cell In sh.UsedRange.SpecialCells(xlCellTypeFormulas)
        If cell.Errors.Item(xlEvaluateToError).Value Then
            'cell.Interior.Color = vbRed
            If ErrRa Is Nothing Then Set ErrRa = cell Else Set ErrRa = Union(cell, ErrRa)
        End If
    Next
    If Not ErrRa Is Nothing Then
        ErrRa.Select    ' выделяем все ячейки с ошибками
        MsgBox "Найдено ошибок в формулах:  " & ErrRa.Cells.Count
    End If
End Sub

Sub ПоискНепустыхЯчеекВСтолбцеМ_вариант1()
    Dim sh As Worksheet, Ra As Range: Set sh = ActiveSheet
    Set Ra = sh.UsedRange.EntireRow.Columns(13)    ' часть столбца М в используемой области листа

    If IsNull(Ra.Text) Then MsgBox "В столбце М присутствуют непустые ячейки"
End Sub

Sub ПоискНепустыхЯчеекВСтолбцеМ_вариант2()
    Dim sh As Worksheet, Ra As Range: Set sh = ActiveSheet
    Set Ra = sh.UsedRange.EntireRow.Columns(13)    ' часть столбца М в используемой области листа
    On Error Resume Next: Err.Clear
    If Not Ra.SpecialCells(xlCellTypeBlanks).Count = Ra.Cells.Count Then
        If Err.Number = 0 Then MsgBox "В столбце М присутствуют непустые ячейки"
    End If
End Sub

[EducatedFool]

Первый макрос можно записать проще:

Sub ВыделяемЯчейкиСОшибками_2()
    On Error Resume Next
    Set ErrRa = ActiveSheet.UsedRange.Cells.SpecialCells(xlCellTypeFormulas, xlErrors)
    If Not ErrRa Is Nothing Then
        ErrRa.Select    ' выделяем все ячейки с ошибками
        MsgBox "Найдено ошибок в формулах:  " & ErrRa.Cells.Count
    End If
End Sub

[Iskin]

Как всегда не точно сформулировал вапрос...
Посмотрел первый макрос в обоих вариантах. Все отрабатывает. Но, есть пожелания. Дело в том, что макрос ищет ошибки в функциях. Хотелось что бы ошибки искались и по заданной маске. В моем случае, Лист, где надо провести проверку, формулы не содержит, а только значения.

[EducatedFool]

Лист, где надо провести проверку, формулы не содержит, а только значения

Попробуйте заменить в макросе xlCellTypeFormulas на xlCellTypeConstants

Хотелось что бы ошибки искались и по заданной маске.

Прикрепите к сообщению файл с ошибками.
Укажите несколько примеров "масок", по которым Вы хотите искать ошибки.

[Iskin]

Сообщение от EducatedFool

Попробуйте заменить в макросе xlCellTypeFormulas на xlCellTypeConstants

попробывал не сработало.

вот пример...
Было бы не плохо если при обноружении ошибок останавливались все последующие макросы.

[valerij]

Сообщение от Iskin

попробывал не сработало.

Все работает, там же есть объединенные ячейки, вот он и показывает пять ошибок, четыре С18-Ф18 и одна, И27.
Снимите объединение и будет две ошибки.

[Iskin]

Сообщение от valerij

Все работает, там же есть объединенные ячейки, вот он и показывает пять ошибок, четыре С18-Ф18 и одна, И27.
Снимите объединение и будет две ошибки.

Точно заменил на xlCellTypeConstants сработало.

Теперь останавливать все последующие макросы нет необходимости.
Спасибо!