ВПР3 (VLOOKUP3) и закрытая книга

[klarmir]

ВПР3 (VLOOKUP3) с закрытой книгой
Уважаемые форумчане.
Помогите пожалуйста!
Как или что сделать чтоб функция ВПР3 (VLOOKUP3)
брала данные из закрытой книги. Я использую вот это:

Function VLOOKUP3(Table As Variant, SearchColumnNum As Integer, _
SearchValue As Variant, ResultColumnNum As Integer)
'улучшенная функция ВПР вводится как формула массива
'ищет указанной значение в указанном столбце и выводит все соответствия из указанного столбца
Dim i&, j&
Dim a
ReDim Out(1 To Table.Rows.Count, 1 To 1) As Variant

a = Table.Value
For i = 1 To Table.Rows.Count
If a(i, SearchColumnNum) = SearchValue Then
j = j + 1
Out(j, 1) = a(i, ResultColumnNum)
End If
Next i
VLOOKUP3 = Out
End Function

она работает только при открытой книге,
Спасибо!

[Казанский]

Попробуйте, должно работать и с открытой, и с закрытой книгой

Function VLOOKUP3(Table As Variant, SearchColumnNum As Integer, _
                  SearchValue As Variant, ResultColumnNum As Integer)
'улучшенная функция ВПР вводится как формула массива
'ищет указанной значение в указанном столбце и выводит все соответствия из указанного столбца
Dim i&, j&
Dim a
If IsObject(Table) Then a = Table.Value Else a = Table
ReDim Out(1 To UBound(a), 1 To 1) As Variant
For i = 1 To UBound(a)
    If a(i, SearchColumnNum) = SearchValue Then
        j = j + 1
        Out(j, 1) = a(i, ResultColumnNum)
    End If
Next i
VLOOKUP3 = Out
End Function