Последовательность открытия файлов

[Jaroslav]

Например, у меня есть в пакпе D:\111 файлы БМЕС1 (D2504).xls, БМЕС2 (D2503).xls, БМЕС3 (D2501).xls, БМЕС4 (D2502).xls.

Dim fs As New FileSystemObject
Dim fl As Folder
Dim fls As Files
Set fl = fs.GetFolder("D:\111")
    Set fls = fl.Files
    For Each f In fls
        Workbooks.Open Filename:=f
    Next

Этот вариант кода откроет сначала файл БМЕС1 (D2504).xls, потом файл БМЕС2 (D2503).xls, потом файл БМЕС3 (D2501).xls, потом файл БМЕС4 (D2502).xls, то есть открытие производится по имени файла.
А мне нужно чтобы сначала открывался БМЕС3 (D2501).xls, потом БМЕС4 (D2502).xls, потом БМЕС2 (D2503).xls, потом БМЕС1 (D2504).xls, то есть чтобы открытие выполнялось по коду в скобках.

[SAS888]

Сохраните полученные имена файлов из нужной папки, например, в массиве. Затем, отсортируйте массив по требуемым критериям. Затем, открывайте файлы из массива по порядку. Например, так:

Sub Main()
    Dim i As Long, j As Long, a(), b(), fls, f, x
    Set fls = CreateObject("Scripting.FileSystemObject").GetFolder("D:\111").Files
    ReDim a(1 To fls.Count, 1 To 2): i = 1
    For Each f In fls
        a(i, 1) = f.Name: a(i, 2) = Split(f.Name, "(")(1): i = i + 1
    Next
    For i = LBound(a, 1) To UBound(a, 1) - 1
        For j = i + 1 To UBound(a, 1)
            If a(i, 2) > a(j, 2) Then
                x = a(i, 1): a(i, 1) = a(j, 1): a(j, 1) = x
                x = a(i, 2): a(i, 2) = a(j, 2): a(j, 2) = x
    End If: Next: Next
    b = Application.Index(a, 0, 1)
    For i = LBound(b) To UBound(b)
        Workbooks.Open Filename:=b(i)
    Next
End Sub

Если требуется, добавьте проверки: существует ли путь, какой формат файла, есть ли в имени файла скобки и т.п. В предложенном макросе это не делается.

[Jaroslav]

Спасибо, SAS888. Я попробую.

[Jaroslav]

Ответ на мой вопрос:

Dim fs As New FileSystemObject
Dim fl As Folder
Dim fls As Files
Dim f As File
Dim str1 As String
Dim i As Integer, c As Integer

Application.ScreenUpdating = False
Application.DisplayAlerts = False
str1 = "D:\111"
Set fl = fs.GetFolder(str1)
Set fls = fl.Files
    i = 0
    Workbooks.Add
    For Each f In fls
        i = i + 1
        Cells(i, 1).Value = Trim(f)
    Next
    c = Columns("A").Rows(65536).End(xlUp).Row
    For i = 1 To c
        Cells(i, 2).FormulaR1C1 = _
            "=MID(RC[-1],FIND(""("",RC[-1],1)+1,FIND("")"",RC[-1],1)-FIND(""("",RC[-1],1)-1)"
        Range("B1").AutoFill Destination:=Range("B1:B" & c), Type:=xlFillDefault
    Next
    Range("A1:B" & c).Sort Key1:=Range("B1")
    ReDim arr(1 To c): For i = 1 To c: arr(i) = Cells(i, 1): Next
    ActiveWindow.Close
    For i = 1 To c
        Workbooks.Open Filename:=arr(i)
    Next
Application.ScreenUpdating = True
Application.DisplayAlerts = True

[SAS888]

Можно и так. Но я не хотел использовать ячейки рабочего листа. Тем более, что я не знаю, какие можно "трогать", а какие нет. Ну, Вам виднее.