Установление даты последнего изменения в поле примечание

[vasyater]

Ребят еще есть к вам просьбо такая штука - я уже обращался к вам на что получил ответ Вроде это уже было.

PHP код:
Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
If Not Intersect(Target, Range("H4:H9")) Is Nothing Then
If MsgBox("Сохранить изменение " & Target.Value & "?", _
vbInformation + vbYesNo, "Изменения в ячейках") = vbYes Then Exit Sub
With Application
.EnableEvents = False: .Undo: .EnableEvents = True
End With
End If
End Sub
в этом коде выходит сообщение диалоговое окно хочу ли я сохранить значение в ячейке ,но теперь нужно еще одну ячейку сделать чтобы в ней отражалась дата изменение этой ячейки - напримерв в ячейке Н4 : Н9
были изменнения чтобы в соседней ячейке была дата последнего изменения
КАК ПРАВИЛЬНО СОВМЕСТИТЬ ДВА КОДА ЧТОБЫ ТО И ТО РАБОТАЛО НА ОДНОМ ЛИСТЕ

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
If Not Intersect(Target, Range("H4:H9")) Is Nothing Then
If MsgBox("Сохранить изменение " & Target.Value & "?", _
vbInformation + vbYesNo, "Изменения в ячейках") = vbYes Then Exit Sub
With Application
.EnableEvents = False: .Undo: .EnableEvents = True
End With
End If
End Sub


Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Cells.Count > 1 Then Exit Sub
If Not Intersect(Target, Range("A1:A1000")) Is Nothing Then
With Target(1, 2)
.Value = Now
.EntireColumn.AutoFit
End With
End If
End Sub

[doober]

Возможно так

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
If Not Intersect(Target, Range("H4:H9")) Is Nothing Then
If MsgBox("Сохранить изменение " & Target.Value & "?", _
vbInformation + vbYesNo, "Изменения в ячейках") = vbYes Then
Target.Offset(0, 1) = Format(Now, "Short Date")
Exit Sub
End If
With Application
.EnableEvents = False: .Undo: .EnableEvents = True
End With
End If
End Sub

[KOSTIK1]

ЧТОБЫ ТО И ТО РАБОТАЛО НА ОДНОМ ЛИСТЕ

Возможно и так

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    If Not Intersect(Target, Range("H4:H9")) Is Nothing Then
        If MsgBox("Сохранить изменение " & Target.Value & "?", _
                  vbInformation + vbYesNo, "Изменения в ячейках") = vbYes Then
            Target.Offset(0, 1) = Format(Now, "Short Date")
            Exit Sub
        End If
        With Application
            .EnableEvents = False: .Undo: .EnableEvents = True
        End With
    End If
    If Not Intersect(Target, Range("A1:A1000")) Is Nothing Then
        With Target(1, 2)
            .Value = Now
            .EntireColumn.AutoFit
        End With
    End If
End Sub