VBA Excel 2003

[SAS888]

Задача понятна. К сожалению, Excel не может обновлять связи в избранных ячейках, но можно обновлять связи с избранными файлами. Решение Вашей проблемы зависит от структуры рабочей книги. Так, например, если столбец "A" содержит связи с одним файлом, столбец "B" с другим, "C" с третьим и т.д., то задача решается просто:

Private Sub Workbook_Open()

    Dim w As Integer, a()
    
'Если концом первой недели месяца считать первое воскресенье месяца, то:

    w = Fix((Day(Date) + Weekday(CStr("01." & Month(Date) _
        & "." & Year(Date)), vbMonday) - 2) / 7) + 1
        
'Но тогда возможна и 6-я неделя (например, март 2008г.)
'А если считать, что первая неделя всегда с 1 по 7, то:

    'w = Fix((Day(Date) - 1) / 7 + 1)
    
    a = ActiveWorkbook.LinkSources(xlExcelLinks)
    ActiveWorkbook.UpdateLink Name:=a(w)
    
End Sub

ПРИМЕЧАНИЕ: файл должен быть сохранен с отключенным обновлением связей и отключенным запросом на обновление.

А если не так, то нужно будет удалить связи на рабочем листе, использовать метод "Select Case" и в коде VBA прописывать нужные ссылки.

[tat-besidovska]

спасибо большое за полезную информацию, Вы правы,что все зависит от структуры моего файла. В столбцах(в моей таблице), в каждой ячейке идет связь с разными файлами, короче надо думать. Подскажите, как прописать в VBA связь с ячейкой в закрытом файле, заранее спасибо

[SAS888]

В VBA не существует метода получения значения из закрытого файла рабочей книги. Эта задача выполняется в результате вызова макроса XLM. Следующий пример, расположенный в модуле "Эта книга",при открытии покажет в окне сообщений значение из закрытой книги, определенное Вами.

'Объявляем функцию:
Private Function GetValue(path, file, sheet, ref)
    Dim arg As String
'Создание аргумента:
    arg = "'" & path & "[" & file & "]" & sheet & "'!" & Range(ref).Range("A1").Address(, , xlR1C1)
'Выполнение макроса XLM:
    GetValue = ExecuteExcel4Macro(arg)
End Function
'Запуск процедуры при открытии файла:
Private Sub Workbook_Open()

'Задаем параметры:
    p = "D:\Temp\"      'Путь к файлу
    f = "MyFile.xls"    'Имя файла
    s = "Лист1"         'Имя листа
    a = "A1"            'Адрес ячейки
    
'Получаем значение из закрытой книги:
    MsgBox GetValue(p, f, s, a)
    
End Sub