Проблема с переходом на следущую страницу

[AlexShp]

Здравствуйте.
Нужен совет по такой проблеме:
Пытаюсь вывести несколько текстбоксов на странице, по достижении нужного количества, добавить страницу, перейти на неё там продолжить вывод.
Страница добавляется, но вывод продолжается на первой странице. Что интересно просто текст выводится на следущей странице, а textbox на той же. Я плохо разбираюсь в объектной модели Word, возможно где то чего то путаю. Вот код (по кусочкам собран на форумах )

Sub AddTxtBox()
   Dim objLeft As Double
   Dim objTop As Double
   Dim objWidth As Double
   Dim objHeight As Double
   
   Dim IntervalHeight As Double
   Dim IntervalWidth As Double
   
   Dim cntRows As Integer
   Dim i As Integer
   
   Dim objTxtBox As Shape
   'Координаты
   objLeft = ConvertCmToPoint(1)
   objTop = ConvertCmToPoint(1)
   'Размеры
   objWidth = ConvertCmToPoint(4.5)
   objHeight = ConvertCmToPoint(2.5)
   'Вертикальный интервал
   IntervalHeight = ConvertCmToPoint(0.5)
   i = 1
   cntRows = 1
   Do While i < 15
      Set objTxtBox = ActiveDocument.Shapes.AddTextbox _
      (msoTextOrientationHorizontal, objLeft, objTop, objWidth, objHeight)
      objTxtBox.TextFrame.TextRange = "Text Box " & "#" & Trim(Str(i))
      objTop = objTop + objHeight + IntervalHeight
      cntRows = cntRows + 1
      If cntRows > 7 Then
         cntRows = 1
         ActiveDocument.Range(ActiveDocument.Range.End - 1, ActiveDocument.Range.End - 1).InsertBreak Type:=wdPageBreak
         objTop = ConvertCmToPoint(1)
         ActiveDocument.Content.InsertAfter Text:=" Next Page" 
      End If
      i = i + 1
   Loop
 End Sub
Function ConvertCmToPoint(ByVal cm As Double) As Double
   ConvertCmToPoint = cm * 28.34646
End Function

[viter.alex]

У метода AddTextbox есть последний необязательный параметр. В статье он не указан, но появляется в подсказке при вводе функции. Этот последний параметр называется Anchor и с его помощью задаётся диапазон, к которогому привязывается вставляемый объект. Чтобы вставить на нужную страницу, нужно задать диапазон, находящийся на нужной странице.
Например,

'Вставит на страницу с первым абзацем
ActiveDocument.Shapes.AddTextbox msoTextOrientationHorizontal,0,0,100,20,ActiveDocument.Paragraphs.First.Range

'Вставит на страницу с последним абзацем
ActiveDocument.Shapes.AddTextbox msoTextOrientationHorizontal,0,0,100,20,ActiveDocument.Paragraphs.Last.Range

[AlexShp]

Сообщение от viter.alex

У метода AddTextbox есть последний необязательный параметр...

Спасибо! Отлично работает!
Нашел ещё другой способ - после вставки новой страницы добавить такой код:

 ActiveDocument.GoTo(wdGoToPage, wdGoToNext).Select

[viter.alex]

Сообщение от AlexShp

Нашел ещё другой способ

Ну это если ты работаешь с выделением. Если же работаешь в фоне, незаметно от пользователя, то выделение не подходит, т.к. будет мешать.

[AlexShp]

Сообщение от viter.alex

Ну это если ты работаешь с выделением. Если же работаешь в фоне, незаметно от пользователя, то выделение не подходит, т.к. будет мешать.

И замедлять наверное. Так что да, согласен.

[viter.alex]

Сообщение от AlexShp

И замедлять наверное.

Не факт. Если отключить обновление экрана, то работа с Selection иногда быстрее, а некоторые вещи можно делать только через выделение.