Напоминание в Excel

[InfoR]

Суть такова:

Имеется книга excel, в нее при помощи веб-запросов с интервалом в 5 минут подгружаются данные, которые нужно постоянно мониторить.
Например:
Сервер1 - онлайн
Сервер2 - онлайн
Сервер3 - офлайн

Через веб-запрос подгружается состояние серверов онлайн или офлайн.
Эта книга excel постоянно свернута, так как параллельно занимаюсь другой работой.

Так вот, можно ли сделать так, что если какой-то сервер ушел в офлайн, на экране выскочило что-то типо напоминания или, например, свернутое окно начало мигать, или раскрылось, короче чтобы на это сразу обращали внимание.

[staniiislav]

Может MsgBox сообщение выводить на процедуру оффлайн

[EducatedFool]

Так а зачем что-то делать?
Насколько я знаю, если веб-запрос обращается к оффлайн серверу, уведомление о недоступности сервера в Excel выскакивает автоматически.

Обычно обращаются за обратным, - скрыть уведомления о временно недоступных серверах...

[maksim_serg]

Declare Function MessageBox Lib "user32" Alias "MessageBoxA" (ByVal hwnd As Integer, _
                                                              ByVal txt As String, _
                                                              ByVal caption As String, _
                                                              ByVal Typ As Integer) As Integer
Declare Function FlashWindow Lib "user32" (ByVal hwnd As Long, ByVal bInvert As Long) As Integer
Declare Function FlashWindowEx Lib "user32" (ByRef pfwi As tFLASHWINFO) As Integer
Declare Function ShowWindow Lib "user32.dll" (ByVal hwnd As Long, ByVal nCmdShow As Long) As Integer
Declare Function Beep Lib "kernel32" (ByVal dwFreq As Long, ByVal dwDuration As Long) As Integer

Type tFLASHWINFO
      cbSize    As Long
      hwnd      As Long
      dwFlags   As Long
      uCount    As Long
      dwTimeout As Long
End Type

Sub myMsgbox() ' выскочило что то типа напоминания
Dim Result As Integer
Result = MessageBox(0, "Сервер отключен", Application.Name, &H20 Or 6)
End Sub

Sub WindowFladh() 'свернутое окно начало мигать
Dim Result As Integer
Dim FWInfo As tFLASHWINFO
With FWInfo
   .cbSize = 20
   .hwnd = Application.hwnd
   .dwFlags = 1 Or 2
   .uCount = 5
   .dwTimeout = 0
End With
Result = FlashWindowEx(FWInfo)
End Sub

Sub WindowActivate() ' или раскрылось
Dim Result As Integer
Result = ShowWindow(Application.hwnd, 3)
End Sub

Sub Action() ' короче, что бы сразу на это обращали внимание
Dim Result As Integer
For i = 0 To 3
Beep 1500, 750
DoEvents
Next i
End Sub