Скопировать скрытый лист внутри книги...

[GieNa]

Всем привет...
Меня мучает один вопрос, как можно сделать следующее:
Есть книга в ней 6 листов, 5 листов с различными формами для заполнения, так вот эти 5 листов должны быть скрыты, а на первом листе должны размещаться кнопки с возможность добавить ту или иную анкету...при этом необходимо задать имя данной анкеты "Анкета1", а при повторном нажатии на кнопку добавления должна быть уже "Анкета2" и т.д.

никак не могу это реализовать, помогите плз...

[EducatedFool]

Делается это просто - всего несколько строк кода.
Но вот файл делать нет ни малейшего желания...

Прикрепите к сообщению файл, объясните, что куда копировать, - и получите готовое решение

[GieNa]

Вот файл, все свои горе макросы я удалил,чтобы не мешались...

[EducatedFool]

А куда надо добавлять скопированную анкету?
На лист с кнопками?

Сделайте несколько макросов наподобие этого:

Sub КопированиеАнкеты1()
    Worksheets("Анкета заемщика ЮР").UsedRange.Copy [a1]
End Sub

и назначьте их кнопкам

Или лист надо копировать целиком?
Если да, то куда его помещать? В ту же книгу (в начало, в конец), или создавать новый файл из одного листа?
В этом случае код будет другим:

Sub КопированиеАнкеты1()
    Application.ScreenUpdating = False    ' отключаем обновление экрана
    With Worksheets("Анкета заемщика ЮР")
        .Visible = -1    ' делаем лист видимым
        .Copy    ' копируем его в новую книгу
        .Visible = 0    ' делаем лист снова скрытым
    End With
End Sub

[GieNa]

Спасибо, а как сделать так, чтобы страница копировалась в ту же книгу и ставилась в конец? И как бытьс именем закладки? Оно будет автоматически менять название, при нажатии на одну кнопку несколько раз, на Анкета(1),Анкета(2) и т.д.?

[GieNa]

Если я ставлю данный код:

Sub КопированиеАнкеты1()
    Application.ScreenUpdating = False    ' отключаем обновление экрана
    With Worksheets("Анкета заемщика ЮР")
        .Visible = -1    ' делаем лист видимым
        .Copy    ' копируем его в новую книгу
        .Visible = 0    ' делаем лист снова скрытым
    End With
End Sub

То создается новая книга и туда копирутся мой лист. Можно ли задать так же имя этой книги вместо Книга1, Книга2 и т.д.

Или же все-таки чтобы лист копировался в конец основной книги и имя его менялось в соответствии от того сколькораз я нажму на кнопку макроса, т.к. анкет может быть 3-4 штуки одинаковых.

[EducatedFool]

Попробуйте так:

Sub КопированиеАнкеты1()
    КопированиеЛиста "Анкета заемщика ЮР"
End Sub

Sub КопированиеАнкеты2()
    КопированиеЛиста "Анкета заемщика ИП"
End Sub

Sub КопированиеЛиста(ByVal ИмяЛиста As String)
    Application.ScreenUpdating = False    ' отключаем обновление экрана
    With Worksheets(ИмяЛиста)
        .Visible = -1    ' делаем лист видимым
        .Copy , Worksheets(Worksheets.Count)      ' копируем его в конец книги
        .Visible = 0    ' делаем лист снова скрытым
        On Error Resume Next
        Do ' присваиваем листу имя
            Err.Clear: i = i + 1: ActiveSheet.Name = "Анкета" & i
        Loop While Err
    End With
End Sub