Как в коде VBA возвратить путь к заранее известному файлу?

[Maxx]

Есть два файла: файл «Трединг.xls» с листом «Блокнот» и файл «Шаблон(Блокнот).csv» с листом «Шаблон(Блокнот)». Оба лежат в одной папке (P.S. Класть их в разные папки для меня нет смысла, так как они все равно работают в паре).

Я написал следующий код (т.е. это отрывок из большого кода):

' Копия Блокнота в Шаблон Транзака
Application.ScreenUpdating = False: Application.DisplayAlerts = False
Sheets("Блокнот").Select
Range("A1:A14").Select
Selection.Copy
ChDir "C:\Documents and Settings\marenkovm\Мои документы\Маренков\Разное"
Workbooks.Open Filename:= _
"C:\Documents and Settings\marenkovm\Мои документы\Маренков\Разное\Шаблон(Бл окнот).csv"
Range("A1").Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Application.CutCopyMode = False
ActiveWorkbook.Save
ActiveWindow.Close

Код, выделенный красным цветом, открывает файл «Шаблон(Блокнот)», который ОБЯЗАН лежать по этому пути. Но если я запускаю макрос на другом компьютере, а данный файл (естественно) лежит в другой папке, то ничего, конечно же, не работает.
Вопрос? Что нужно изменить, чтобы к файлу «Шаблон(Блокнот).csv» автоматически прописывался бы путь, по которому находится файл «Трединг.xls»???

[IgorGO]

Workbooks.Open Filename:= ActiveWorkBook.Path & "\Шаблон(Блокнот).csv"

[EducatedFool]

Sub test()
    Application.ScreenUpdating = False: Application.DisplayAlerts = False

    PS = Application.PathSeparator: TemplatePath = ThisWorkbook.Path    ' получаем путь этого файла
    If Right(TemplatePath, 1) <> PS Then TemplatePath = TemplatePath & PS    ' дописываем в конец пути символ "\"
    TemplatePath = TemplatePath & "Шаблон(Блокнот).csv"    ' добавляем к пути имя файла

    Dim Template As Workbook:    Set Template = Workbooks.Open(TemplatePath) ' пытаемся открыть файл "Шаблон(Блокнот).csv"
    If Template Is Nothing Then MsgBox "Не удалось открыть файл  " & TemplatePath, vbCritical, "Ошибка": Exit Sub ' выход из процедуры, если файл не удалось открыть
    
    ' если код продолжает выполняться, значит, файл "Шаблон(Блокнот).csv" открылся
    ThisWorkbook.Worksheets("Блокнот").Range("A1:A14").Copy ' копируем диапазон ячеек из этого файла (в котором выполняется код)
    
    Template.Worksheets(1).Range("A1").PasteSpecial Paste:=xlPasteValues, SkipBlanks:=False ' вставляем значения ячеек
    
    Template.Close True ' закрываем файл "Шаблон(Блокнот).csv" с сохранением изменений
    ' или    Template.Save  ' сохраняем файл "Шаблон(Блокнот).csv" (не закрывая его)
End Sub

[Maxx]

ВОТ ЭТО ДА-А-А!!! Все замечательно работает! СПАСИБО!

[Maxx]

EducatedFool, и Вам Спасибо! Тоже замечательно работает!

Может быть и я когда-нибудь дойду до такого мастерства!