Макрос для всех листов

[as-is]

Уважаемые, помогите править макрос. Я долго добирался до макроса, который бы выполнялся на всех листах книги. Ниже образец найденного.
-----------------------------------------------------------------
Public Sub DoToAll()
'декларирование переменой
Dim ws As Worksheet
For Each ws In Worksheets
'разместите свой код для выполнения на каждом листе
ws.Range("A1") = "Пример"
Next
End Sub
-----------------------------------------------------------------
Макрос-пример на каждом листе в ячейке ставит надпись "Пример". Мне необходимо, чтобы выполнялся другой макрос:
Проблема, - как разместить ранее полученный макрос удаления пустых строк между "For" "Next". Сам код для удаления ниже
-----------------------------------------------------------------
Sub DeleteEmptyRows()
LastRow = ActiveSheet.UsedRange.Row - 1 + ActiveSheet.UsedRange.Rows.Count
Application.ScreenUpdating = False
For r = LastRow To 1 Step -1
If Application.CountA(Rows(r).Columns( 9)) = 0 Then Rows(r).Delete
Next r
End Sub
-----------------------------------------------------------------
СПАСИБО. долго мучаюсь.

[EducatedFool]

Можно, например, так:

Sub DoToAll()
    Application.ScreenUpdating = False ' отключаем обновление экрана
    Dim ws As Worksheet    'декларирование переменой
    For Each ws In Worksheets
        ws.Activate    ' активируем лист
        DeleteEmptyRows    ' выполняем макрос
    Next
End Sub

Sub DeleteEmptyRows()
    LastRow = ActiveSheet.UsedRange.Row - 1 + ActiveSheet.UsedRange.Rows.Count
    For r = LastRow To 1 Step -1
        If Application.CountA(Rows(r).Columns(9)) = 0 Then Rows(r).Delete
    Next r
End Sub

Или так:

Sub DeleteEmptyRowsToAll()
    Application.ScreenUpdating = False    ' отключаем обновление экрана
    Dim ws As Worksheet    'декларирование переменой
    For Each ws In Worksheets
        LastRow = ws.UsedRange.Row - 1 + ws.UsedRange.Rows.Count
        For r = LastRow To 1 Step -1
            If Application.CountA(ws.Rows(r).Columns(9)) = 0 Then ws.Rows(r).Delete
        Next r
    Next
End Sub

PS: Не понял, что означает CountA(Rows(r).Columns(9))
Зачем считать количество заполненных ячеек для диапазона из 1 ячейки???
Ладно бы, если всю строку проверяли...
А то можно написать и попроще:

Sub DeleteEmptyRowsToAll()
    Application.ScreenUpdating = False    ' отключаем обновление экрана
    Dim ws As Worksheet    'декларирование переменой
    For Each ws In Worksheets
        LastRow = ws.UsedRange.Row - 1 + ws.UsedRange.Rows.Count
        For r = LastRow To 1 Step -1
            If ws.Rows(r).Cells(9) = "" Then ws.Rows(r).Delete
        Next r
    Next
End Sub

Или вообще без цикла:

Sub DeleteEmptyRowsToAll()
    Application.ScreenUpdating = False    ' отключаем обновление экрана
    On Error Resume Next
    Dim ws As Worksheet    'декларирование переменой
    For Each ws In Worksheets
        ' удаляем сразу все строки, в которых в 9-м столбце - пусто
        ws.Columns(9).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
    Next
End Sub

[as-is]

Огромное спасибо, - быстро и оперативно. Сначала не получилось, но подправил код удаления и стало все ОК.
Возникла ещё одна проблемка - на первом листе у меня ячейки, при активации на которых выполняется макрос (своеобразное меню). Так это "меню" тоже удаляется.
Можно ли сделать так, чтобы ... со второго листа и до последнего шло удаление.
То есть как не трогать первый лист. Спасибо.

[EducatedFool]

Sub DeleteEmptyRowsToAll()
    Application.ScreenUpdating = False    ' отключаем обновление экрана
    On Error Resume Next
    Dim ws As Worksheet    'декларирование переменой
    For Each ws In Worksheets
        If ws.Index > 1 Then    ' кроме первого листа
            ' удаляем сразу все строки, в которых в 9-м столбце - пусто
            ws.Columns(9).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
        End If
    Next
End Sub

[as-is]

Не дочитал - броузер не все выдал. Строка
CountA(Rows(r).Columns(9))
означает, что удаление строк идет по проверке ячеек в 9 колонке - это сейчас не принципиально.
Другие Ваши варианты ещё не пробовал - получилось пока с первым.
***
Проблема с первым листом-описано выше.
После этого попробовал вставлять картинки и привязывать к ним макросы - картинки не удаляются. Поэтому один из вариантом найден.

Ради интереса - как все-таки оставить "неприкосновенным" первый лист. Макрос выполнялся бы со второго. Спасибо.

[as-is]

Так быстро, что не успеваю. Преклоняюсь, иду осваивать. Спасибо.

[yogoru]

Доброго времени суток всем!!!!

У меня имеется макрос вида:

Sub Защита()

Const MyPassword = "1111"
With ActiveSheet
.Unprotect Password:=MyPassword
.EnableOutlining = True
.Protect Password:=MyPassword, Contents:=True, Scenarios:=True, UserInterfaceOnly:=True
End With

End Sub

необходим запуск макроса по Всем листам!!!
на сколько я понял мне необходим примерно вот такой цикл в него вписать:

Dim ws As Worksheet
For Each ws In ThisWorkbook.Worksheets

Next

Но как это сделать понять не могу!!! Только начал с VB колдовать и не очень что-то получается!

Помогите ПЛЗ!

[EducatedFool]

Например, так:

Sub ЗащитаВсехЛистов()

Const MyPassword = "1111"
Dim ws As Worksheet

For Each ws In ThisWorkbook.Worksheets

ws.Unprotect Password:=MyPassword
ws.EnableOutlining = True
ws.Protect Password:=MyPassword, Contents:=True, Scenarios:=True, UserInterfaceOnly:=True

Next

End Sub

[yogoru]

ОГРОМНОЕ СПАСИБО!
Всё работает!