Excel - Почта

[valerij]

Зачем то закрыли тему, а тут вопрос и работа встала!!!!!.
Яндекс изменил настройки
http://help.yandex.ru/mail/mail-clients/ssl.xml#other
а как мне изменить, ведь у нас ранее порт не был прописан?

Private Sub SendAttachment()
    Application.DisplayAlerts = False
        iFileName$ = ThisWorkbook.Path & "\ xxx.xls"
    ThisWorkbook.SaveCopyAs Filename:=iFileName$
    If Send_Mail("получатель@yandex.ru", "отправитель@yandex.ru", "Тема", iFileName$) Then 
       MsgBox "Письмо успешно отправлено", vbInformation, ""
    Else
       MsgBox "Не удалось отправить письмо", vbCritical, ""
    End If
    Kill PathName:=iFileName$
    Application.DisplayAlerts = True
End Sub

Function Send_Mail(ByVal MailTo As String, _
                   ByVal MailFrom As String, _
                   ByVal MailSubject As String, _
                   ByVal MailAttachment As String, _
                   Optional ByVal MailText As String = "") As Boolean
    Const cdoConfigURL = "http://schemas.microsoft.com/cdo/configuration/"
    Const SmtpServer = "smtp.yandex.ru"
    Const SendUsername = "отправитель@yandex.ru" '"адрес отправителя"
    Const SendPassword = "хххххххххххххх" '"его пароль"
    On Error Resume Next
    Set cdoConfig = CreateObject("CDO.Configuration")
    With cdoConfig.Fields
        .Item(cdoConfigURL & "sendusing") = 2
        .Item(cdoConfigURL & "smtpauthenticate") = 1
        .Item(cdoConfigURL & "smtpserver") = SmtpServer
        .Item(cdoConfigURL & "sendusername") = SendUsername
        .Item(cdoConfigURL & "sendpassword") = SendPassword
        .Update
    End With
    Set cdoMessage = CreateObject("CDO.Message")
    With cdoMessage
        Set .Configuration = cdoConfig
        .BodyPart.Charset = "koi8-r"
        .From = MailFrom
        .To = MailTo
        .Subject = MailSubject
        .TextBody = MailText
        .AddAttachment MailAttachment
        .Send
    End With
    Set cdoMessage = Nothing: Set cdoConfig = Nothing
    Send_Mail = (Err.Number = 0)
End Function

[IgorGO]

Валера,
на Яндексе описано как настроить почтового клиента на работу с почтовым сервером яндекс. видимо каким-то из них пользуешься и ты, вот и займись настройкой, делается это ручками, а макрос - не трогай, тебе это противопоказано.

когда настроишь программу макрос будет работать как работал раньше.

Удачи!

[doober]

Валера,use Google

 
 .Item(cdoConfigURL & "smtpserverport") = 465 
 .Item(cdoConfigURL & "smtpusessl") = 1

[valerij]

Сообщение от doober

Валера,use Google

 
 .Item(cdoConfigURL & "smtpserverport") = 465 
 .Item(cdoConfigURL & "smtpusessl") = 1

Добавил в макрос и всё заработало, время срабатывания изменилось, >> , но то фигня!!

Спасибо!!!
(\__/)
(='.'=)
E[:]|||[:]З
(")_(")