Word VBA как вставить разрыв принудительный в формулу ?

[bdfy]

Если щелкнуть мышью по формуле набранной в новом редакторе 2007/10 ворда то там есть опция - "вставить принудительный разрыв". иногда чрезвычайно полезная опция.
вопрос как вставить такой разрыв программно ? что это за знак ? клик мышью при записи макроса не работает - т.е через запись не посмотреть.
в мануале инфы не нашел.
пробовал текст выражения выводить до и после вставки разрыва
Set f = oDoc.Range.OMaths
f(1).linearize
Debug.Print f(1).Range.text
одно и то же показывает... ( идеи есть у кого ?
chrw(11) если вставить формулу разрывает.
с chrw(10) тоже ничего не дает. какой знак еще попробовать можно ?
у кого ворд английский - скажите как эта фукнция оригинально называется, может хоть погуглить смогу нормально...

[Вождь]

Помогут команды MS Word, начинающиеся со слова Equation.
Вставка разрыва в формуле:

Application.Run "EquationManualBreak"

[bdfy]

истина да, гдето в этих краях. хотя справка ничего похожего на EquationManualBreak и не показывает.
если в Word поставить на место разрыва курсор и запустить макрос - работает.
из екселя тоже работает.

Set oDoc = GetObject(ThisWorkbook.Path & "\отчет0.docx")

Debug.Print oDoc.Application
oDoc.Application.Run "EquationManualBreak"

большой вопрос вот только как на эту самую позицию курсор выставить.... может "EquationManualBreak" параметры какие понимает...

[bdfy]

OMathBreaks.Add еще похоже из этой оперы. но работать заставить ен получается ((
OMathBreaks.Сount даже не работает ((

[Вождь]

Сообщение от bdfy

…справка ничего похожего на EquationManualBreak и не показывает…

По командам справка не помощник. Краткие описания есть в списке команд: Alt+F8 > Макросы из "Команды Word" > Выбираем команду и читаем поле "Описание".

Сообщение от bdfy

…как на эту самую позицию курсор выставить…

    ' курсор
    With ActiveDocument.OMaths(1).Functions(1).Range
        .Collapse wdCollapseEnd
        .Select
    End With
    ' разрыв
    Application.Run "EquationManualBreak"

Сообщение от bdfy

…OMathBreaks …. работать заставить…

Так работает:

ActiveDocument.OMaths(1).Breaks.Count

[bdfy]

тогда и add должно работать. оно же именно эти разрывы и считает
oDoc.OMaths(1).Breaks.Add (а вот тут должен быть range). для формулы я range сформулировать не могу ((
по идее как то так ведь должно быть ?

oDoc.OMaths(1).Breaks.Add (oDoc.OMaths(1).Range(start:=10, End:=10))

ан, не работает (( разрыв предполагается в уже набранную программой формулу вставлять.

[Вождь]

Все работает:

Dim M As Word.OMath
Dim R As Word.Range
    
    Set M = ActiveDocument.OMaths(1)
    Set R = M.Functions(1).Range
    R.Collapse wdCollapseStart ' wdCollapseEnd
    M.Breaks.Add R

Если еще не догадались, то поясню, что разрыв нельзя вставить внутри функции (Function.Range), только перед или после. Также нельзя вставить в начале и конце формулы.

[bdfy]

Если еще не догадались, то поясню, что разрыв нельзя вставить внутри функции (Function.Range), только перед или после.

я не догадался как определить нужное мне место в формуле ((
предположим что я знаю конкретное место в формуле и отмечу его спец. знаком $ например - как этот знак заменить на разрыв ? т.е как конкретную позицию в формуле указать где разрыв сделать ? Range на число знаков у меня сделать не вышло ((

[Вождь]

Пример поиска и замены символа "$" разрывом во всех формулах документа:

    ActiveDocument.Range(0, 0).Select
    With Selection.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Forward = True
        .Wrap = wdFindStop
        .Text = "$"
    End With
    Do While Selection.Find.Execute
        If Selection.OMaths.Count = 1 Then
            Selection.Delete
            Selection.OMaths(1).Breaks.Add Selection.Range
        End If
        Selection.Collapse wdCollapseEnd
    Loop

[bdfy]

без селекшенов никак нельзя обойтись ? через range чисто ? документ программно набирается - обьект формулы мне известен.