Запись символа из регистра в строку (Assembler: TASM)

[chipdrunk]

Нужно:
Поменять местами соседние слова в строке (1 со 2; 3 с 4 ...) Если слов нечетное количество - последнее с первым.
Мною был разработан примерный алгоритм обработки строки:

Посимвольное считывание и нахождение пробела мне удалось реализовать.
Далее мне нужно добавить найденный символ в строки TEMPWORD и Mbuffer - согласно алгоритму.
Я пробовал: Lea TEMPWORD, [SI], например. В лучшем случае удавалось получить в итоге бинарник - вместо текста в файле.
Понятно, что я не правильно добавляю символ в строку.
Собственно, на этой операции пока, что остановился.
Еще интересует: как в дальнейшем сложить строки Mbuffer и TEMPWORD
Помогите, пожалуйста.

CODE SEGMENT		 
ASSUME CS: CODE, DS:CODE 	 
org 100h	
Start:

;/// OPEN VANILLA FILE (1)
       MOV AH, 3DH
       MOV AL, 0
       MOV DX, OFFSET FILE
       int 21h  
       mov [vfhandle], ax



;/// CREATE A NEW FILE (2)
       mov ah,3Ch 
       mov cx,0
       mov dx, 0
       mov DX, OFFSET NEWFILE
       int 21h
       mov [nfhandle], ax



;/// READING VANILLA FILE (3)
       mov bx, vfhandle
       mov ah, 3Fh 
                 ;mov dx, FILE
       mov cx, 512
       mov dx,OFFSET Buffer
       int 21h  

SUB BX, BX

;/// DATA PROCESSING
       lea SI, BUFFER
       sub CH,CH
       mov CL, ' ' ;nums
       mov ax, cx
       cmp CX,0
       jne m1
       jmp exit
MOV BH, 1
m1:   
       cmp [SI], byte ptr ' '
       jnbe sk
       ; найден пробел
        
       
       jmp exit

sk:  ; символ не пробел

       /// ДОБАВЛЕНИЕ В TEMPWORD ТЕКУЩЕГО СИМВОЛА (SI - индекс)    
       inc  SI
       loop m1

m3:  
       mov CX,AX
       lea DI, Buffer 

exit:

;/// SAVE MODIFIED BUFFER TO A NEW FILE (5)
       mov ah,40h 
       mov bx, nfhandle 
       lea dx, Buffer 
       mov cx, 512
       int 21h 

;/// CLOSE A NEW FILE (6)
       mov ah, 3eh ; закрытие
       MOV BX, nfhandle
       int 21h

;/// CLOSE VANILLA FILE (7)
       mov ah, 3eh ; закрытие
       MOV BX, vfhandle
       int 21h

ret

nfhandle    dw 1
vfhandle    dw 1 
Mbuffer DB 512 dup(' ')  
Buffer DB 512 dup(' ')
TEMPWORD DW 512 dup(' ')
NEWFILE  DB  'K:\NEWFILE.txt',0
FILE  DB  'K:\FILE.txt',0
	
CODE ENDS	
END Start

[R71MT]

Сообщение от chipdrunk

Запись символа из регистра в строку
Нужно:
Поменять местами соседние слова в строке (1 со 2; 3 с 4 ...)
Если слов нечетное количество - последнее с первым.

Непонятно, что ты хочешь менять: соседнии символы или слова?

[chipdrunk]

Из файла считывается строка - буфер, состоящая из слов, разделенных пробелом. Естественно, чтобы поменять местами слова - мне нужно найти пробел, как - либо образом манипулировать с словами. Я задумал сохранять слово в переменной и вставлять после следующего слова. Так как веду поиск пробела я посимвольным сравнением текущего символа с пробелом - можно сохранять не пробелы в то самое временное слово. Насколько я знаю, в асм нет функций, типа find. Вы знаете иной способ выделения слов из строки?

[R71MT]

Сообщение от chipdrunk

Насколько я знаю, в асм нет функций, типа find.
Вы знаете иной способ выделения слов из строки?

..типа find - это repne scasb. Можещь почитать про неё.
А алгоритм, не знаю.. может есть и другие.
Твою мыслю можно воплотить например так..

Нужны 2 буфера: для слова(TEMP) и для выходной строки(OUT).
Под слово хватит байт-16, а выходной сравнять с входным. Алго примерно такой:

1. Первое слово запоминаешь в буфере(TMP);
2. Второе слово сразу отправляешь в выходной буфер(OUT);
3. Вставляешь следом первое слово;
4. Очищаешь временный буфер.
5. Мотаешь, если не конец строки..

Вот пример на FASM'e.
Подразумевается, что считанные из файла данные находятся в BUFF.
Длинна строки лежит в LEN. Изменённая строка будет в OUTSTR:

; fasm code... //com-file
; xchg - слов в строке
;--------------------------------
org  100h
jmp  start

buff     db   'ABC DEFG HI JKLMN OPQ RS TUVWX YZ 01234562016', '$'
len      =    $ - buff          ;длина строки
outStr   db   len dup('$')      ;такой-же выходной буфер
temp     db   16 dup(0)         ;временный буфер для слова

start:  mov   ah,9
        mov   dx,buff
        int   21h

;настраиваем регистры..
        mov   bx,outStr
        mov   si,buff
        mov   cx,len

;копируем левое слово во-временный буфер
;SI = источник, DI = приёмник..
@begin: mov   di,temp
        call  storeWord
        jcxz  @print         ;если строка кончилась

;копируем правое слово сразу в выходной буфер(OUT)
        mov   di,bx          ;адресация через ВХ
        call  storeWord
        push  si cx

;отправляем левое слово из TEMP в OUT
;DI уже установлен..
        mov   si,temp
@@01:   lodsb
        or    al,al
        je    @@02
        stosb
        jmp   @@01
@@02:   mov   bx,di          ;адресация к OUT через ВХ

;забиваем TEMP нулями для сл.слова
        xor   ax,ax
        mov   cx,16
        mov   di,temp
        rep   stosb

;возвращаемся в буфер со-строкой
        pop   cx si
        or    cx,cx            ;всю строку проверили?
        je    @print
        loop  @begin           ;нет - продолжаем..

;проверим временный буфер
@print: cmp   byte[temp],0
        je    @okey
        mov   di,bx            ;осталось чётное слово!
        mov   si,temp
@clear: lodsb
        or    al,al
        je    @okey
        stosb                  ;заберём его от туда..
        jmp   @clear

;выводим результат на экран!
@okey:  mov   al,10            ;перевод строки..
        int   29h
        mov   ah,9
        mov   dx,outStr
        int   21h

@exit:  xor   ax,ax
        int   16h
        int   20h              ;выход в DOS !!!

;-------------------------------------------------------------
storeWord:       ;<----- Процедура отправляет из SI в DI
        lodsb
        cmp   al,' '
        je    @@stop
        stosb
        loop  storeWord
@@stop: stosb           ;пробел-разделитель
        ret

[chipdrunk]

Спасибо за столь прямой "пинок", вопрос решен!