доработка макроса

[Kate-Rina]

Еще раз обращаюсь за помощью.

помогите доработать макрос, пожалуйста)

Идея такая:
Лист проверка - идеальный вариант блоков, относительно которого идет сравнение блоков регионов.
Лист Невыходы блоков - результат- сюда добавляются данные из листа Проверка, отсортированные по столбцу 15 -непустые.

в данный момент: вручную на листе Блоки регионы надо отсортировать сначала первый регион, потом запустить макрос, потом вручную снова отфильтровать следующий регион и тд.

нужно: чтобы это происходило автоматически.
возможно такое?

спасибо

[SAS888]

1. Не путайте сортировку с фильтрацией. Вас трудно понять.
2. В приложенном Вами файле большое количество формул. Поэтому, каждый раз при открытии, сохранении и т.п., а также после выполнения каких-либо действий макросом, Excel пересчитывает ячейки. А это очень долго.
3. Пример в виде рабочего файла приложить не могу, ибо у Вас в файле (в формулах и макросах) есть ссылки на несуществующую (у меня) книгу. Поэтому, предлагаю попробовать такой код:

Sub Main()
    Dim i As Long, x As New Collection, a()
    Application.Calculation = xlManual: Application.ScreenUpdating = False
    Sheets("блоки регионы").Activate
    a = Range([B2], Cells(Rows.Count, 2).End(xlUp)).Value: On Error Resume Next
    For i = 1 To UBound(a, 1)
        If a(i, 1) <> "" Then x.Add a(i, 1), CStr(a(i, 1))
    Next: On Error GoTo 0
    If x.Count > 1 Then
        For i = 1 To x.Count
            [A:K].AutoFilter Field:=2, Criteria1:=x(i)
            KopirLong 'Запуск Вашего макроса
        Next: ActiveSheet.ShowAllData
    End If
     Application.Calculation = xlAutomatic: Application.ScreenUpdating = True
End Sub

Небольшие пояснения:
а) Запрещаем пересчет ячеек и обновление экрана.
б) Создаем массив a из значений столбца "B", ибо с элементами массива работать существенно быстрее, чем с ячейками рабочего листа.
в) Создаем коллекцию x, содержащую уникальные (неповторяющиеся) значения из массива a.
г) Организуем цикл, в котором поочередно применяем автофильтр по столбцу "B" с критериями из коллекции x. При этом, после каждой фильтрации запускаем Ваш макрос (в примере кода это "KopirLong". А какой нужно, Вы не оговариваете).
д) Разрешаем пересчет ячеек и обновление экрана. Именно в этот момент времени Excel на некоторое время "задумается" (см. п.2)