Удаление ячеек всех кроме красных и желтых

[ТРИУМФ]

Есть таблица с остатками. excel 2010. нужно удалить все ячейки корме желтых и красных в диапазоне "матрица" со сдвигом влево. найденные темы
Как удалять ячейки с помощью VBA , Удаление строк в зависимости от заливки , Удаление пустых ячеек в MS Excel
----
ну что то я совсем глупый и не могу их вместе сложить и написать. Помогите плиз

[Казанский]

Без оптимизации (работает долго!)

Sub bb()
Dim i&, j&, c&
Application.ScreenUpdating = False
For i = 7 To Cells(Rows.Count, "B").End(xlUp).Row
    For j = Cells(i, Columns.Count).End(xlToLeft).Column To 6 Step -1
'        Cells(i, j).Select
        c = Cells(i, j).Interior.Color
        If c <> vbRed And c <> vbYellow Then Cells(i, j).Delete xlShiftToLeft
    Next
Next
Application.ScreenUpdating = True
End Sub

[Казанский]

Вот так уже более-менее приемлемо

Sub bb()
Dim i&, j&, c&, r As Range
Application.ScreenUpdating = False
For i = 7 To Cells(Rows.Count, "B").End(xlUp).Row
    Set r = Nothing
    For j = Cells(i, Columns.Count).End(xlToLeft).Column To 6 Step -1
'        Cells(i, j).Select
        c = Cells(i, j).Interior.Color
        If c <> vbRed And c <> vbYellow Then _
            If r Is Nothing Then Set r = Cells(i, j) Else Set r = Union(r, Cells(i, j))
    Next
    If Not r Is Nothing Then r.Delete xlShiftToLeft
Next
Application.ScreenUpdating = True
End Sub

[ТРИУМФ]

Все супер спасибо.