Особый поиск

[ExeiLj]

Всем привет!

Суть такова:
надо в коде VBA организовать поиск по столбцу, чтобы он искал поле с ОДНИМ восклицательным знаком.

Просто есть поля где два восклицательных знака, а есть где три или вообще ноль. Поэтому надо научить его искать поля, где в тексте имеется только один восклицательный знак.

Вообще не знаю как такое условие задать, может кто даст наводку?

[Hugo121]

Даю наводку

Sub tt()
For Each cc In [a1:a4]
MsgBox UBound(Split(cc, "!"))
Next
End Sub

Ещё можно сравнить исходную длину строки с длиной строки без "!".

Чтоб ускорить - можно сперва найти с помощью Find ячейку, потом её проверить на количество "!".

[SAS888]

Пусть требуется найти и выделить все ячейки, содержащие 1 восклицательный знак в диапазоне "A1:A7".

Sub Main()
    Dim x As Range, y As Range
    For Each x In [A1:A7]
        If x Like "*!*" And Not x Like "*!*!*" Then If y Is Nothing Then Set y = x Else Set y = Union(y, x)
    Next
    If Not y Is Nothing Then y.Select
End Sub

[nilem]

Еще вариант (скоро зачет по RegExp )

Sub ertert()
Dim pz As Range
For Each pz In [a1:a7]
    If REColor(pz) Then pz.Interior.ColorIndex = 36
Next
End Sub

Function REColor(r As Range) As Boolean
With CreateObject("vbscript.regexp")
    .Global = True: .Pattern = "!"
    With .Execute(r.Value)
        REColor = .Count = 1
    End With
End With
End Function

[EducatedFool]

nilem, зачет по RegExp принят на отлично

Но зачем пускать в ход тяжелую артиллерию, если простейшие функции справляются?

Sub ertert()
    Dim pz As Range
    For Each pz In [a1:a7]
        If Len(pz) - Len(Replace(pz, "!", "")) = 1 Then pz.Interior.ColorIndex = 36
    Next
End Sub

Но проще, конечно, как Hugo предложил:

Sub ertert2()
    Dim pz As Range
    For Each pz In [a1:a7]
        If UBound(Split(pz, "!")) = 1 Then pz.Interior.ColorIndex = 36
    Next
End Sub

[ExeiLj]

Всем большое спасибо! Воспользовался этим

If UBound(Split(pz, "!")) = 1 Then