Остановка и перезапуск макроса в цикле

[Jarik]

добрый день.

Работая с одной из библиотек фунцкий столкнулся со следующей проблемой.

Допустим есть некоторая библиотечная функция

Function A(x)

при этом ее вычисление занимает некоторое значимое время (около секунды)

проблема в следующем.
есть sheet "DATA" со столбцом аргуметов x (столбец А) и столбцом функций A(x) (столбец B)
Мне необходимо несколько раз поменять аргументы и сохранить соответствующие значения функции A на отдельный лист "RESULT".
В коде это выглядило бы так

Sub SaveValues()

    With Sheets("DATA")
        'n - nuber of experiments
        For i = 1 To n
            For j = 1 To 100
                .Cells(j, 1) = Rnd()
            Next j
        Next i
        
        .Cells(1, 2).Resize(100, 1).Copy
        Sheets("RESULT").Cells(1, j).PasteSpecial xlPasteValues
    End With
End Sub

Однако при выполнении кода функция A не успевает вычислиться при каждой итерации цикла и чоответственно я сохраняю только значения "#N/A"
как с этим можно бороться?

P.S. вызов функции из VBA не предлагать - не работает.
P.S.S К сожалению не могу выслать пример, т.к. функция A работает только вместе со спецефическим приложением у меня на работе.

Заранее спасибо!

[Казанский]

Попробуйте так:

Sub SaveValues()
Application.Calculation = xlCalculationManual
With Sheets("DATA")
    n = 3 'n - nuber of experiments
    For i = 1 To n
        For j = 1 To 100
            .Cells(j, 1) = Rnd()
        Next j
        Application.Calculate
        .Cells(1, 2).Resize(100, 1).Copy
        Sheets("RESULT").Cells(1, i).PasteSpecial xlPasteValues 'сменил j на i
    Next i  'конец цикла тут!
End With
Application.Calculation = xlCalculationAutomatic
End Sub

[Казанский]

На самом деле, цикл по j не нужен, достаточно в A1:A100 записать формулу =СЛЧИС(), она будет обновляться при пересчете:

Sub SaveValues()
Application.Calculation = xlCalculationManual
With Sheets("DATA")
    n = 3 'n - nuber of experiments
    For i = 1 To n
        Application.Calculate
        .Cells(1, 2).Resize(100, 1).Copy
        Sheets("RESULT").Cells(1, i).PasteSpecial xlPasteValues 'сменил j на i
    Next i  'конец цикла тут!
End With
Application.Calculation = xlCalculationAutomatic
End Sub