Excel 2007. Диаграммы...

[nikolai_P]

Всем, привет!
Пытаюсь написать макрос построения красивой диаграммы вот такой:

делаю это следующим образом:
формат рядов данных->формат объемной фигуры->выбираем рельеф, устанавливаем ширину и высоту сверху.


Пробовал с помощью макроредактора определить нужные параметры - Не получилось.

ВОЗМОЖНО РЕШИТЬ ПОСТАВЛЕННУЮ ЗАДАЧУ С ПОМОЩЬЮ МАКРОСА?

[IgorGO]

рисуете на странице два графика, со всеми одинаковими данными, только с разными рельефами, запускаете любую отладку, берете на просмотр оба графика ищете свойство, которым они отличаются. все. в зависимости от удачи, через 5 минут или 5 часов поиска находите результат.

[mchip]

Как вариант :
ActiveSheet.ChartObjects(1).Chart.C hartStyle = 30
Если нужно подробнее пиши...

[mchip]

Или так:
ActiveChart.SeriesCollection(1).Poi nts(2).Format.ThreeD.BevelTopType = msoBevelCircle

[nikolai_P]

To mchip
.ChartStyle = 30
Уже ближе, добавился объем. Теперь как изменить рельеф?

To IgorGO

запускаете любую отладку

Буду признателен если расспишите более подробно предложенный Вами способ. Я с таким не сталкивался!

[Acro]

Если оно есть, то должно быть упомянуто тут -
msdn: Chart Object Members

[mchip]

ActiveChart.SeriesCollection(1).Poi nts(2).Format.ThreeD.BevelTopType = index()

Где index():
1 - рельеф круг
2 - рельеф крутой склон
...
5 - рельеф крест

ну и т.д.
Там почему то пробел лишний отображается, при копировании исправь.

[nikolai_P]

Вот код , как получить диаграмму на первом посте!

   
 Set r1 = NewSheet.Range(Cells(4, C_Tab), Cells(3 + CountSheets, C_Tab))
Set r2 = NewSheet.Range(Cells(4, 1), Cells(3 + CountSheets, 1))


Set NewChart = ThisWorkbook.Charts.Add
NewChart.Name = "Динамика " & Sheet(CountSheets).Name & "-" & Sheet(1).Name

With NewChart
    .ApplyChartTemplate ("C:\Documents and Settings\Николай_2\Application Data\Microsoft\Templates\Charts\Столбиковая.crtx")
    .PageSetup.PaperSize = xlPaperLegal 'формат листа диаграммы
    .ChartType = xlColumnClustered 'тип диаграммы
    .Legend.Delete    'убираем легенду
    .SetSourceData Source:=NewSheet.Range("A4")
    .SeriesCollection(1).Values = r1    ' значения
    .SeriesCollection(1).XValues = r2    ' подписи
    .SeriesCollection(1).ApplyDataLabels     'добавить подписи на диаграмму
    .SeriesCollection(1).DataLabels.Position = xlLabelPositionCenter    ' позиция подписей
    .SeriesCollection(1).DataLabels.ShowValue = True    ' показывать значения
    .SeriesCollection(1).DataLabels.Font.Bold = True
    .SeriesCollection(1).DataLabels.Font.Size = 24
    .SeriesCollection(1).DataLabels.Font.Name = "Verdana"
    .SeriesCollection(1).DataLabels.Font.Color = RGB(255, 255, 255)
    .SeriesCollection(1).Interior.Color = RGB(0, 139, 153)
    .SeriesCollection(1).Format.ThreeD.BevelTopDepth = 8    ' здесь устанавливается следующий параметр (формат рядов данных->формат объемной фигуры->Рельеф->сверзу->высота и ширина
    .SeriesCollection(1).Format.ThreeD.BevelTopInset = 8
    .SeriesCollection(1).Format.ThreeD.BevelTopType = msoBevelAngle    ' тип рельефа
    .ChartGroups(1).Overlap = 25     ' здесь устанавливаем параметры ряда->перекрытие ряда и боковой зазор
    .ChartGroups(1).GapWidth = 55
    With .Axes(xlValue)    ' редактируем оси
        .Border.Color = RGB(0, 139, 153)
        .Border.Weight = xlMedium
        .TickLabels.Font.Color = RGB(0, 139, 153)
        .TickLabels.Font.Bold = True
        .TickLabels.Font.Size = 24
        .TickLabels.Font.Name = "Verdana"
    End With
    With .Axes(xlCategory)
        .Border.Color = RGB(0, 139, 153)
        .Border.Weight = xlMedium
        .TickLabels.Font.Color = RGB(0, 139, 153)
        .TickLabels.Font.Bold = True
        .TickLabels.Font.Size = 24
        .TickLabels.Font.Name = "Verdana"
    End With
    With .Axes(xlValue).MajorGridlines
        .Border.Color = RGB(0, 139, 153)
        .Border.Weight = xlHairline
    End With

    .PlotArea.Width = 640    ' уменьшаем слегка диаграмму
    .PlotArea.Left = 240
End With
Application.ScreenUpdating = True
ActiveWindow.Zoom = 86

P.S.
Этой строкой

 .ApplyChartTemplate ("C:\Documents and Settings\Николай_2\Application Data\Microsoft\Templates\Charts\Столбиковая.crtx")

я применяю шаблон, поскольку на моей диаграмме должен быть ярлычок. Как его вставить на диаграмму из файла я не нашел! Если знаете подскажите!

[mchip]

Что есть ярлычок?

[nikolai_P]

Это *.gif картинка!