Матрицы в VBA

[Lyudmila721]

Подскажите, пожалуйста, нужно сформировать матрицу. Правильно ли решение? 0-ые элементы надо ли указывать в условии?? или они по-умолчанию?
0 0 0 0 5 5 5 5
0 0 0 5 0 5 5 5
0 0 5 0 0 5 5 5
0 5 0 0 0 5 5 5
5 5 5 5 5 5 5 5

Решение
Sub Zadanie_2()
Const N=5, M=8 ‘ Размерность матрицы
Dim B(N,M) As Integer
Dim I , J As Integer ‘ I-номер строки, J-номер столбца
For I=1 To N
For J=1 To M
If ((J<=5) And (I+J=N+1)) OR ((I=5) OR (J =6) OR (J =7) OR (J =8) ) Then B(I,J) = 5
Else
B(I,J) = 0
End If
Next J
Next I
‘вывод матрицы на Лист 2
WorkSheets(“Лист2”).Select
For I=1 To N
For J=1 To N
Cells(I+1,J)=B(I,J)
Next J
Next I
End Sub

[EducatedFool]

У меня вот что получилось:

Sub test()
    Const N = 5, M = 8    ' Размерность матрицы
    Dim B(1 To N, 1 To M) As Integer
    Dim I As Integer, J As Integer  ' I-номер строки, J-номер столбца
    For I = 1 To N
        For J = 1 To M
            B(I, J) = 5 ' по умолчанию
            If I + J <> 6 And I < 5 And J < 5 Then B(I, J) = 0
        Next J
    Next I
    'вывод матрицы на Лист 2, начиная с ячейки
    Worksheets("Лист2").Cells(1, 1).Resize(N, M).Value = B
End Sub

Можно и так: (по умолчанию в массиве нули)

Sub test()
    Const N = 5, M = 8    ' Размерность матрицы
    Dim B(1 To N, 1 To M) As Integer
    Dim I As Integer, J As Integer  ' I-номер строки, J-номер столбца
    For I = 1 To N
        For J = 1 To M
            If Not (I + J <> 6 And I < 5 And J < 5) Then B(I, J) = 5
        Next J
    Next I
    'вывод матрицы на Лист 2, начиная с ячейки
    Worksheets("Лист2").Cells(1, 1).Resize(N, M).Value = B
End Sub

PS: А можно обойтись и без конструкции If ... Then ...

    For I = 1 To N
        For J = 1 To M
             B(I, J) = 5 * ((I + J <> 6) * (I < 5) * (J < 5) + 1)
        Next J
    Next I
    'вывод матрицы на Лист 2, начиная с ячейки