masm32 - После создания окна оно закрывается:(

[Wardrag]

Вот такая вот процедура окна:

WndProc proc hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM

.IF uMsg==WM_DESTROY 

invoke PostQuitMessage,NULL 

.ELSEIF uMsg ==  WM_MOUSEMOVE

invoke MessageBox,hWnd,chr$("okno"),chr$("okno"),0

.ELSE

invoke DefWindowProc,hWnd,uMsg,wParam,lParam 
ret
.ENDIF
xor eax,eax
ret

WndProc endp
end start

ВинАсм генерит дофига кода,который мне,собственно,и не нужен(куча дочерних окон и элементов управления к примеру).Потому пишу с нуля.
Почему окно закрывается ? Я даже убрал все сообщения - результат один и тот же.Мне нужно,чтобы оно не закрывалось.

[Stilet]

.ELSE

invoke DefWindowProc,hWnd,uMsg,wParam,lPar am
ret
.ENDIF
xor eax,eax
ret

Интересный финт...

[Wardrag]

Как ни крути,а всё равно закрывается.

[Stilet]

А ты уверен что именно на этом участке проблема?

[Wardrag]

Без понятия.Ошибок-то не возникает.:

.386
.model flat, stdcall
option casemap:none

include C:\masm32\include\windows.inc
include C:\masm32\include\user32.inc
include C:\masm32\include\kernel32.inc
include \masm32\macros\macros.asm
includelib C:\masm32\lib\user32.lib
includelib C:\masm32\lib\kernel32.lib

WinMain proto :DWORD,:DWORD,:DWORD,:DWORD

.DATA
ClassName db "SimpleWinClass",0
AppName db "Our First Window",0

.DATA?
hInstance HINSTANCE ?
CommandLine LPSTR ?

.CODE 
start:
invoke GetModuleHandle, NULL 

mov hInstance,eax
invoke GetCommandLine
mov CommandLine,eax
invoke WinMain, hInstance,NULL,CommandLine,SW_SHOWDEFAULT
invoke ExitProcess, eax 
WinMain proc hInst:HINSTANCE,hPrevInst:HINSTANCE,CmdLine:LPSTR,  CmdShow:DWORD

LOCAL wc:WNDCLASSEX 
LOCAL msg:MSG
LOCAL hwnd:HWND

mov wc.cbSize,SIZEOF WNDCLASSEX 
mov wc.style, CS_HREDRAW or CS_VREDRAW
mov wc.lpfnWndProc, OFFSET WndProc
mov wc.cbClsExtra,NULL
mov wc.cbWndExtra,NULL
push hInstance
pop wc.hInstance
mov wc.hbrBackground,COLOR_WINDOW+1
mov wc.lpszMenuName,NULL
mov wc.lpszClassName,OFFSET ClassName
invoke LoadIcon,NULL,IDI_APPLICATION
mov wc.hIcon,eax
mov wc.hIconSm,eax
invoke LoadCursor,NULL,IDC_ARROW
mov wc.hCursor,eax
invoke RegisterClassEx, addr wc 
invoke CreateWindowEx,NULL,\
ADDR ClassName,\
ADDR AppName,\
WS_OVERLAPPEDWINDOW,\
CW_USEDEFAULT,\
CW_USEDEFAULT,\
CW_USEDEFAULT,\
CW_USEDEFAULT,\
NULL,\
NULL,\
hInst,\
NULL

mov hwnd,eax
invoke ShowWindow, hwnd,CmdShow 
invoke UpdateWindow, hwnd 
invoke GetMessage, ADDR msg,NULL,0,0
.IF (!eax)

.WHILE TRUE ; Enter message loop
invoke GetMessage, ADDR msg,NULL,0,0
.BREAK .IF (!eax)
invoke TranslateMessage, ADDR msg
invoke DispatchMessage, ADDR msg
.ENDW
.ENDIF
mov eax,msg.wParam
ret

WinMain endp

WndProc proc hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM

.if uMsg == WM_CREATE


invoke MessageBox,hWnd,chr$("shit"),chr$("shit"),0
invoke ExitProcess,0


.elseif uMsg == WM_DESTROY

invoke PostQuitMessage,0
xor eax,eax
ret

.ENDIF

WndProc endp
end start
end

Окно ведь сначала сообщения обрабатывает,так что без разницы,что прописано в главной процедуре окна.
Пример скопировал с гугла).

[Stilet]

invoke GetMessage, ADDR msg,NULL,0,0
.IF (!eax)

Это то зачем? Убери. Тут твои проблемы видимо.
Вот как в шаблоне для МАСМ выглядит

INVOKE	UpdateWindow,hwnd
	.WHILE TRUE
		invoke	GetMessage,ADDR msg,0,0,0
		.BREAK .IF (!eax)
		invoke	TranslateMessage,ADDR msg
		invoke	DispatchMessage,ADDR msg
	.ENDW

Нет перед циклом никаких условий.

[yuran666666]

да у вас там вообще полная лажа-так окна не строят!
ВинАсм ничего лишнего не добавляет вроде как
Читайте Iczelion'а вообщем, чтобы более таким кодом тут никого не смешить

[Wardrag]

Ну дак блин MDI мне не нужен и SDI,мне просто нужно тупо пустое окно( Он там генерит прально всё,но удалять приходится офигенное количество кода.

Разобрался.Сделал отдельный асм файлик....всем спасибо за участие.

[yuran666666]

Сообщение от Wardrag

Ну дак блин MDI мне не нужен и SDI,мне просто нужно тупо пустое окно( Он там генерит прально всё,но удалять приходится офигенное количество кода.

Разобрался.Сделал отдельный асм файлик....всем спасибо за участие.

местный гура _mikl на васме писывал темку на форуме "сам себе Iczelon"-если хочешь оптимизировать простое окно (и не выкинуть оттуда жизненно важное! ) то туда довольно поучительно

[Mikl___]

Wardrag
Простейшее окно на MASM'e

.686P 
.model flat, stdcall
option casemap:none
includelib user32.lib
includelib kernel32.lib
include windows.inc
extern _imp__CreateWindowExA@48:dword
extern _imp__DefWindowProcA@16:dword
extern _imp__DispatchMessageA@4:dword
extern _imp__GetMessageA@16:dword
extern _imp__ExitProcess@4:dword
extern _imp__RegisterClassA@4:dword
.code
start:	xchg ebx,eax
	mov edi,offset wTitle
        mov esi,400000h
	push edi
	push ebx
	push COLOR_WINDOW+1
	push 10011h
	push ebx
	push esi
	push ebx
	push ebx
	push offset WndProc
	push ebx
	push esp
	call _imp__RegisterClassA@4
	push ebx	   
	push esi
        shl esi,9;esi=CW_USEDEFAULT
	push ebx	
	push ebx	
	push esi	
	push esi	
	push esi	
	push esi	
	push WS_OVERLAPPEDWINDOW + WS_VISIBLE
	push edi; szWinTitle			
	push edi; lpszClassName
	push ebx
	call _imp__CreateWindowExA@48	;создать окно
	mov ebp,esp
message_loop: push ebx  ;цикл обработки сообщений
	push ebx
	push ebx
	push ebp 
	call _imp__GetMessageA@16	
	push ebp
	call _imp__DispatchMessageA@4     ;вернуть управление Windows        
	jmp short message_loop
WndProc:
        cmp dword ptr [esp+8],WM_DESTROY;cmp Msg,WM_DESTROY
	je short @@WM_DESTROY
        jmp _imp__DefWindowProcA@16   ;все сообщения, не обрабатываемые в функции WndProc, направляются на обработку по умолчанию	
@@WM_DESTROY: push ebx    ;завершение программы
	call _imp__ExitProcess@4
	wTitle 	db 	'Iczelion Tutorial #3:A Simple Window in masm',0
end start