Условие для макроса

[sergiksergik]

Доброго суток.
Записал макрос, который берет число из ячейки и делает необходимые операции с ним. Потом следующее и так далее, но в некоторых ячейках чисел может и не быть, а макрос будет их оттуда брать. Как поставить условие, что бы еслии нету числа то макрос пропускал эту ячейку и все операции связанные с ней.
Так же условие по цвету. т.е. допустим красный цвет, не работает и выводит сообщение с текстом"бббббла"
Спасибо.

И еще один вопрос, тоже про условие макроса. В определенную ячейку вносим значение (допустим 1 или 2 или 3 или......), при нажатии кнопки для выполнения макроса, он взависимости от значения выполняет необходимое действие.

еще раз спасибо

[EducatedFool]

Как поставить условие, что бы еслии нету числа то макрос пропускал эту ячейку и все операции связанные с ней.
Так же условие по цвету. т.е. допустим красный цвет, не работает и выводит сообщение с текстом"бббббла"

Sub test()
    Dim cell As Range
    For Each cell In [a3:a33]
        If IsNumeric(cell) Then    ' в ячейке находится число
            cell.Next = cell * 2    ' в ячейку справа пишем число, умноженное на 2
        End If

        If Trim(cell.Value) <> "" Then   ' в ячейке находится число или текст
            cell.Next.Next = "ячейка непустая"

            If cell.Font.Color = vbRed Then    ' в ячейке цвет шрифта - красный
                cell.Font.Bold = True    ' выделяем ячейку жирным шрифтом
            End If

            If cell.Interior.Color = vbGreen Then    ' цвет заливки ячейки - зелёный
                cell = ""    ' очищаем ячейку
            End If
        End If
    Next
End Sub

В определенную ячейку вносим значение (допустим 1 или 2 или 3 или......), при нажатии кнопки для выполнения макроса, он взависимости от значения выполняет необходимое действие.

Sub test2()
    Select Case [d3].Value ' в зависимости от значения в ячейке d3
        Case 1: [d5] = "текст"
        Case 2: [d7] = "текст2"
        Case 3 To 5: [d5] = "текст345"
        Case Is > 14: [d5] = "число больше 14"
        Case Else: Макрос3
    End Select
End Sub

[sergiksergik]

Спасибо....
Буду пробовать..

А пока если можно еще вопрос..
Необходимо что бы после заполнения формы, нажатие "Внести" и данные вносились в соответствующие колонки


help.rar

[EducatedFool]

Замените строки

    Dim iLastRow As Long
    iLastRow = Cells(Rows.Count, 1).End(xlUp).Row
    Cells(iLastRow + 1, 1) = Me.ComboBox3
    Cells(iLastRow + 2, 1) = CDbl(Me.TextBox2)
    Cells(iLastRow + 3, 1) = CInt(Me.ComboBox4)

на такие:

    Range("c65000").End(xlUp).Offset(1) = Me.ComboBox3
    Range("d65000").End(xlUp).Offset(1) = CDbl(Me.TextBox2)
    Range("e65000").End(xlUp).Offset(1) = CInt(Me.ComboBox4)

[sergiksergik]

Огромное спасибо... Всегда выручаете...

[sergiksergik]

Если ячейка А6 равна B4 то запускается Макрос 1
если нет то ничего

Помогите, как это написать?

[EducatedFool]

Если ячейка А6 равна B4 то запускается Макрос 1
если нет то ничего

If [a6] = [b4] Then Макрос1

[pivas]

If [A6] = [A4] Then Application.Run "Макрос 1"

[sergiksergik]

Почти догадался сам (Then не вставлял...)

Спасибо...
с меня за все пиво!!!!