Меню для книги

[tae1980]

Задача: условно делим все возможное множество книг на две категории: рабочие и остальные. Нужна создать меню которое:
* появляется при запуске любой рабочей книги,
* не дублируется при открытие новых рабочих книг,
* запускает макросы из надстройки, с которой работают все рабочие книги.
* присутствует пока открыта хотя бы одна рабочая книга и пропадает когда закрывается последняя рабочая книга.

Научился создавать меню, ранее были примере, но вот с остальным проблема...
Может быть стоит меню привязать к надстройке? Рабочая книга открывает настройку, а она создает меню.

[SAS888]

Что-то не совсем понятно. Создайте надстройку и "запихайте" туда все, что нужно. Надстройка не видна (если, конечно, не нужно) и всегда открыта. Все открываемые книги могут использовать все, что есть в надстройке. А что еще нужно-то? Что Вы понимаете (а я не понимаю) под словами

Меню для книги

[EducatedFool]

Начнём с того, что для этого надо перехватывать все события в Excel.

Делается это примерно так:

В модуль книги пишем:

Private Sub Workbook_Open()
    Set App.AppEv = Application
End Sub

В стандартный модуль пишем:

Public App As New ClassApp

Создаём модуль класса с именем ClassApp.
Туда вставляем следующий код:

Public WithEvents AppEv As Application

Private Sub AppEv_NewWorkbook(ByVal wb As Workbook)
    LogWI "AppEv_NewWorkbook", "Создана новая книга excel"
End Sub

Private Sub AppEv_SheetActivate(ByVal sh As Object)
    If UCase(Left(sh.Name, 5)) = "Нужное название листа" Then
        ActiveWindow.Zoom = 100
        ActiveWindow.View = xlNormalView
        LogW "AppEv_SheetActivate", sh.Parent.Name & "  " & sh.Name
    End If
End Sub

Private Sub AppEv_WorkbookNewSheet(ByVal wb As Workbook, ByVal sh As Object)
    LogWI "AppEv_WorkbookNewSheet", "Добавлен лист в книгу  " & wb.Name
End Sub

Private Sub AppEv_WorkbookOpen(ByVal wb As Workbook)
    LogWI "AppEv_WorkbookOpen", "wb.Name = " & wb.Name
    If wb.Name = ThisWorkbook.Name Then Exit Sub

    If КнигаРабочая Then ЧтотоДелаем
End Sub

И так далее... там множество событий.
Обрабатывая некоторые из них, Вы сможете выполнять определённые действия при открытии / закрытии книг.

[EducatedFool]

Может быть стоит меню привязать к надстройке? Рабочая книга открывает настройку, а она создает меню.

Именно так.
Надстройка (с вышеуказанным кодом) создаёт при запуске панель инструментов, изначально делая её невидимой (свойство .visible = false)

Далее, создаём некую функцию, которая, получая в качестве параметра книгу Excel, определяет, является ли она "рабочей":

Function КнигаРабочая(ByVal wb As Workbook) As Boolean
    If wb.Worksheets(1).Cells(2, 5) = "Некий текст" Then КнигаРабочая = True
End Function

Нам понадобится ещё одна функция:

Function ОтсталисьЛиОткрытыеРабочиеКниги() As Boolean
    Dim wb As Workbook
    For Each wb In Workbooks
        If КнигаРабочая(wb) Then ОтсталисьЛиОткрытыеРабочиеКниги = True: Exit Function
    Next
End Function

Далее всё просто.
В модуль класса пишем код:

Public WithEvents AppEv As Application ' эта строка уже была

Private Sub AppEv_WorkbookActivate(ByVal Wb As Workbook)
    Меню.Visible = КнигаРабочая(Wb)
End Sub

Private Sub AppEv_WorkbookBeforeClose(ByVal Wb As Workbook, Cancel As Boolean)
    Меню.Visible = ОтсталисьЛиОткрытыеРабочиеКниги
End Sub

Private Sub AppEv_WorkbookDeactivate(ByVal Wb As Workbook)
    Меню.Visible = ОтсталисьЛиОткрытыеРабочиеКниги
End Sub

Private Sub AppEv_WorkbookOpen(ByVal Wb As Workbook)
    Меню.Visible = КнигаРабочая(Wb)
End Sub