Selection - как объеденить???

[Sensygirl]

Подскажите пожалуйста, как можно сделать так, чтобы макрос добавлял новое выделение строки к уже имеющемуся выделению группы строк???!!!
Другими словами, работал как Ctrl+клик мышью.

Вот просто выделение одной строки, по которой кликнули
Sub macrosStr()
ActiveCell.EntireRow.Select
End Sub

а как сделать, чтобы при новом клике выделялась не другая строка, а стали выделенные обе? и т.д. (три, ..., много).

[EducatedFool]

а как сделать, чтобы при новом клике выделялась не другая строка, а стали выделенные обе? и т.д. (три, ..., много).

Очень просто. Нажмите Shift + F8. А потом выделяйте строки.

[IgorGO]

вставьте код в модуль листа, двойной щелчек по любой ячейке будет добавлять все новые и новые строки к уже отмеченным, до бесконечности...

Dim Rg As Range

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Excel.Range, Cancel As Boolean)
  If Rg Is Nothing Then
    Set Rg = Rows(ActiveCell.Row)
  Else
    Set Rg = Application.Union(Rg, Rows(ActiveCell.Row))
  End If
  Rg.Select
End Sub

[Sensygirl]

Ой как классно, спасибо огромнейшее! Теперь бы научиться при повторном клике убирать выделение ))) ну, передумал человек, нужно бы сделать переключатель....

[EducatedFool]

Теперь бы научиться при повторном клике убирать выделение )))

Учитесь

Dim Rg As Range

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Excel.Range, Cancel As Boolean)
    If Rg Is Nothing Then
        Set Rg = Target.EntireRow
    Else
        If Intersect(Target, Rg) Is Nothing Then
            Set Rg = Union(Rg, Target.EntireRow)
        Else
            Dim tempRa As Range, ro As Range
            For Each ro In Rg.Rows
                If Intersect(Target, ro) Is Nothing Then
                    If tempRa Is Nothing Then
                        Set tempRa = ro
                    Else
                        Set tempRa = Union(tempRa, ro)
                    End If
                End If
            Next
            Set Rg = tempRa
        End If
    End If
    Rg.Select
End Sub

[Sensygirl]

хм, иногда при кликах вываливаются ошибки.. а иногда срабатывает. Кажется ошибка возникает при попытке выделить несуществующую область, когда снимается последний Select и rg становится пустым. Тогда Rg.Selection не может выполниться. Ну в целом направление я поняла, спасибо большущее!!!

[EducatedFool]

Кажется ошибка возникает при попытке выделить несуществующую область, когда снимается последний Select и rg становится пустым.

Действительно, не учёл этот момент.

Теперь всё работает без ошибок:

Dim Rg As Range

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Excel.Range, Cancel As Boolean)
    Cancel = True: On Error Resume Next
    If Rg Is Nothing Then
        Set Rg = Target.EntireRow
    Else
        If Intersect(Target, Rg) Is Nothing Then
            Set Rg = Union(Rg, Target.EntireRow)
        Else
            Dim tempRa As Range, ro As Range
            For Each ro In Rg.Rows
                If Intersect(Target, ro) Is Nothing Then
                    If tempRa Is Nothing Then
                        Set tempRa = ro
                    Else
                        Set tempRa = Union(tempRa, ro)
                    End If
                End If
            Next
            Set Rg = tempRa
        End If
    End If
    Rg.Select
End Sub

[Sensygirl]

Вот спасибо все работает, да. Даже думать не пришлось ))

[Sensygirl]

Ан-нет, чуть чуть подумать пришлось, самую капельку ))
Сделала это все не по двойному клику, а по одинарному, и только по определенному столбцу