Проверка на повторное открытие

[ЯИмя]

Возникла такая проблема и я, как начинающий, решения найти не могу, хотя оно, возможно, простое.
Имеется функция, которая открывает экселевский файл.
Вот её код:

Public Function OpenData(Path As String, Name As String, Optional HiddenMode As Boolean) As Object 

If Right(Path, 1) <> "\" Then Path = Path & "\" 
Dim XLApp As New Excel.Application 
Set OpenData = XLApp.Workbooks.Open(Path & Name) 
If HiddenMode Then OpenData.Hidden = True 
Set XLApp = Nothing 

End Function

А вот и проблемы:

1. Независимо от параметра HiddenMode рабочая книга Эксель всегда открывается в скрытом режиме. Хотя дальнейший код исправно берёт оттуда данные, записывает, сохраняет и закрывает книгу. Всё в порядке.
В принципе, неважно, в каком режиме открывается книга, лишь бы читалась программой. А вдруг понадобится эта функция в другом случае, когда книга нужна не скрытая, да и вообще, хотелось бы знать, почему так происходит.

2. Если прервать выполнение кода и не закрыть Экселевскую книгу, она, естественно, остаётся открытой, но её не видно. И, если запустить код на выполнение, открывается ещё один экземпляр этой книги.
В общем, в первый раз, когда я тестировал свой код, я на это не обращал внимания, потом комп завис и я увидел в диспетчере задач на вкладке "Процессы" штук 25-30 процессов EXCEL.EXE.
И все скрытые, так как в том же диспетчере задач, на вкладке "Приложения" - ни одного Экселя!
Так вот, как проверить в коде функции, не открыт ли уже запрашиваемый файл?

[Pavel55]

Попробуйте

'Source: http://j-walk.com/ss/excel/tips/tip54.htm
Private Function WorkbookIsOpen(wbname) As Boolean
'   Returns TRUE if the workbook is open
    Dim x As Workbook
    On Error Resume Next
    Set x = Workbooks(wbname)
    If Err = 0 Then WorkbookIsOpen = True _
        Else WorkbookIsOpen = False
End Function

[ЯИмя]

Большое спасибо, но всё равно не работает.
В любом случае, открыт ли файл или нет, моя функция (OpenData) открывает новый экземпляр файла, и опять же в скрытом режиме.
Я сделал вот так:

Public Function OpenData(Path As String, Name As String, Optional HiddenMode As Boolean) As Object

If Right(Path, 1) <> "\" Then Path = Path & "\"
Dim XLApp As New Excel.Application
If Not WorkbookIsOpen(Name) Then
    Set OpenData = XLApp.Workbooks.Open(Path & Name)
End If
If HiddenMode Then OpenData.Hidden = True
Set XLApp = Nothing

End Function

И в любом случае, в Вашей, Pavel55, функции, Err = 9 и WorkbookIsOpen всегда = False!
Почему так?
Ведь в диспетчере задач виден Эксель, и код берёт с файла Эксель данные, то есть, ясно видно, что он открыт, но почему его не видит VB?
И почему он, чёрт возьми, всегда открывается скрытым???

[дмидми]

У объекта Workbook нет свойства Hidden.

Попробуй после
Set OpenData = XLApp.Workbooks.Open(Path & Name)
вывести книгу в люди:
OpenData.Windows(1).Visible = True

[ЯИмя]

Всё правильно:

Сообщение от дмидми

У объекта Workbook нет свойства Hidden.

А у Excel.Application - есть.
Всеобщими усилиями нашли такое решение:

Public Function OpenData(Path As String, Name As String, Optional VisibleMode As Boolean) As Object

If Right(Path, 1) <> "\" Then Path = Path & "\"
If Not IsWorkbookOpened(Path & Name) Then
    Dim XLApp As New Excel.Application
    Set OpenData = XLApp.Workbooks.Open(Path & Name)
    If VisibleMode Then XLApp.Visible = True
    Set XLApp = Nothing
Else
    Set OpenData = Workbooks(Name)
End If

End Function

Function IsWorkbookOpened(ByVal FileName As String) As Boolean
    Dim FF As Integer
    FF = FreeFile
    On Error Resume Next
    Open FileName For Binary Lock Read As #FF
    IsWorkbookOpened = (Err.Number <> 0)
    On Error GoTo 0
    Close #FF
End Function

Или ещё попроще, вот такое:

Public Function OpenData(Path As String, Name As String, Optional VisibleMode As Boolean) As Object

If Right(Path, 1) <> "\" Then Path = Path & "\"
    Dim FF As Integer
    FF = FreeFile
    On Error Resume Next
    Open Path & Name For Binary Lock Read As #FF
    IsWorkbookOpened = (Err.Number <> 0)
If Err.Number = 0 Then
    On Error GoTo 0
    Close #FF
    Dim XLApp As New Excel.Application
    Set OpenData = XLApp.Workbooks.Open(Path & Name)
    If VisibleMode Then XLApp.Visible = True
    Set XLApp = Nothing
Else
    Set OpenData = Workbooks(Name)
End If
End Function

Всё работает, поздравьте меня!