Вопрос о копировании ячеек в VBA

[Depressive]

Здравствуйте!

В рабочей книге есть лист "ПРИХОД", его первая строка содержит заголовки колонок и управляющие кнопки.
Некий макрос, по неким условиям создает новый лист, например, "ИЖЕВСК", надо скопировать первую строку из листа "ПРИХОД" в лист "ИЖЕВСК" и установить в последнем такие же ширины колонок и форматы ячеек, как и в исходном листе "ПРИХОД".

При простом:

Sheets("ПРИХОД").Select
Sheets("ПРИХОД").Rows(1).Copy
Sheets("ИЖЕВСК").Select
Sheets("ИЖЕВСК").Rows(1).Select
Sheets("ИЖЕВСК").Paste

в лист "ИЖЕВСК" также копируются кнопки, что недопустимо, и не копируются ширины столбцов

В результате написал работающую, но жутко громоздкую конструкцию:

Sub copyHeader()
    Dim ss As String
    Dim ns As String
    Dim srcSh As Worksheet
    Dim newSh As Worksheet

    ss = "ПРИХОД"   ' имя исходного листа
    ns = "ИЖЕВСК"   ' имя нового листа

    Set srcSh = Sheets(ss)  ' исходный лист
    Set newSh = Sheets(ns)  ' новый лист

    newSh.Select    ' переход на новый лист

    newSh.Rows(1).RowHeight = 30    ' высота первой строки заголовка

    For i = 1 To 12  ' цикл по полям заголовка
        newSh.Cells(1, i).Value = srcSh.Cells(1, i).Value   ' копируем значение

        newSh.Cells(1, i).NumberFormat = "@"    ' текстовый формат

        newSh.Cells(1, i).Borders(xlEdgeLeft).Weight = xlThin   ' границы
        newSh.Cells(1, i).Borders(xlEdgeRight).Weight = xlThin
        newSh.Cells(1, i).Borders(xlEdgeTop).Weight = xlThin
        newSh.Cells(1, i).Borders(xlEdgeBottom).Weight = xlThick

        newSh.Cells(1, i).Interior.ColorIndex = srcSh.Cells(1, i).Interior.ColorIndex   ' фоновый цвет

        newSh.Cells(1, i).HorizontalAlignment = xlCenter    ' выравнивание
        newSh.Cells(1, i).VerticalAlignment = xlCenter

        newSh.Cells(1, i).Font.Name = "Arial"   ' гарнитура
        newSh.Cells(1, i).Font.FontStyle = "bold"
        newSh.Cells(1, i).Font.Size = 10    ' кегль

        newSh.Columns(i).ColumnWidth = srcSh.Columns(i).ColumnWidth ' ширина колонки
    Next i
    newSh.Range("A2").Select    ' идем на A2 для вставки
End Sub

Пожалуйста посоветуйте, как проще скопировать всю первую строку (исключая посторонние элементы на ней - кнопки) на новый лист.
Хотелось бы упростить цикл с последовательным копированием их свойств ячеек на новый лист.

Заранее благодарю!

[Скрипт]

Depressive, попробуйте использовать вместо команды "Paste" команду "PasteSpecial".

[staniiislav]

если правильно понял, примерно так:

Sub copyHeader()
    Dim ss$, ns$, srcSh As Worksheet, newSh As Worksheet

    ss = "ПРИХОД"   ' имя исходного листа
    ns = "ИЖЕВСК"   ' имя нового листа

    Set srcSh = Sheets(ss)  ' исходный лист
    Set newSh = Sheets(ns)  ' новый лист
    
    srcSh.Rows("1:1").Copy  ' копируем строку из листа приход
    newSh.Rows("1:1").PasteSpecial Paste:=xlPasteValues ' вставляем значения в строку в лист ижевск
    newSh.Rows("1:1").PasteSpecial Paste:=xlPasteFormats    ' вставляем форматы в строку в лист ижевск
    newSh.Rows("1:1").PasteSpecial Paste:=xlPasteColumnWidths   ' вставляем ширину столбцов в лист ижевск
    Application.CutCopyMode = False ' убираем выделения после копирования из листа приход
    
    newSh.Activate
    newSh.Range("A1").Select
End Sub

[Depressive]

Огромное спасибо, staniiislav!
Как раз то, что нужно!