Выборка из таблицы с помощью формы

[Vladimir_Der]

Уважаемые программисты и любители VBA, думаю тема избитая, но я недавно этим занимаюсь и не могу найти решения, помогите пожалуйста
Как пример: В таблице в столбце "Отдел" Иванов повторяется три раза и в столбце "№ выезда" 'номер 1230 повторяется три раза, т.е в столбце "код" имеется три одинаковых записи Иванов1230
Код получается: столбец "Отдел"&столбец "№ выезда(А2=B2&C2).
При заполнении СB1 Иванов и ТВ2 1230 формы в ТВ3 автоматически записывается код который нужно найти в таблице.
Затем на форме в текст боксы TB4,TB5,TB6 автоматически заносятся соответствующие значения строк по столбцам из таблицы.
Далее, помогите пожалуйста !
Если по коду в таблице найдено записей больше чем одна...
Как сделать так, чтобы в TB4,TB5,TB6 формы циклично (при нажатии кнопки на форме"Следующая запись" отобразились последующие данные , соответствующие коду.

Описание задачи есть в самом файле в коде VBA на форме.
Заранее благодарен

[Aleksandr H.]

Один с вариантов

Dim iRecordCount As Integer
Dim iCurrRecord As Integer
Dim aRowsNr() As Integer

Private Sub CommandButton2_Click()
    If iRecordCount > 0 Then
        If iCurrRecord < iRecordCount - 1 Then
            iCurrRecord = iCurrRecord + 1
        Else
            iCurrRecord = 0
        End If
    End If
    With Sheets("Лист1")
        UserForm1.TB4.Text = .Cells(aRowsNr(iCurrRecord), 4)
        UserForm1.TB5.Text = .Cells(aRowsNr(iCurrRecord), 5)
        UserForm1.TB6.Text = .Cells(aRowsNr(iCurrRecord), 6)
        MsgBox "Нашел в строке " + CStr(aRowsNr(iCurrRecord))
    End With
End Sub



' автоматическая подстановка данных в форму
Private Sub TB2_Change()
    
    Dim iRecord As Integer
    
    Dim firstAddress
    Dim i As Range 'выбираем переменную
    Set i = Лист1.Range("A:A") ' переменная равна диапазону на листе
    
    Dim sh As Worksheet 'выбираем переменную для листа
    Set sh = Sheets("Лист1") ' переменная равна названию листа
    sh.Select ' переменная равна названию листа
    UserForm1.TB3.Text = UserForm1.CB1.Text + UserForm1.TB2.Text ' получаем КОД
    iRecordCount = Application.WorksheetFunction.CountIf(i, TB3.Value)
    If iRecordCount = 0 Then Exit Sub
    Label7.Caption = "Найдено записей: " & iRecordCount
    ReDim aRowsNr(iRecordCount - 1)
    
    Set n = Columns.Item(1).Find(UserForm1.TB3.Text, , xlValues, xlWhole) ' n - переменная и может быть любой
    If Not n Is Nothing Then
        firstAddress = n.Address
        iRecord = 0: aRowsNr(iRecord) = n.Row
        Do
            Set n = Columns.Item(1).FindNext(n)
            If n Is Nothing Then
                GoTo DoneFinding
            Else
                If n.Address = firstAddress Then Exit Do
                iRecord = iRecord + 1
                aRowsNr(iRecord) = n.Row
            End If
        Loop
        
        
DoneFinding:
        iCurrRecord = 0
        UserForm1.TB4.Text = sh.Cells(n.Row, 4)
        UserForm1.TB5.Text = sh.Cells(n.Row, 5)
        UserForm1.TB6.Text = sh.Cells(n.Row, 6)
        MsgBox "Нашел в строке " + CStr(aRowsNr(iCurrRecord))
    End If
End Sub

[Vladimir_Der]

Александр, большое спасибо за участие, попробую разобраться с кодом, но пока не работает, спотыкается на строчке

UserForm1.TB4.Text = .Cells(aRowsNr(iCurrRecord), 4), при просмотре выдает значение iCurrRecord=0 (Пробую по Иванову где три записи)

и выдает ошибку out of range

Следующие постоянные
Dim iRecordCount As Integer
Dim iCurrRecord As Integer
Dim aRowsNr() As Integer

я поместил во внутрь блока
Private Sub CommandButton2_Click()

иначе сразу выдавалась ошибка
Может быть в этом и ошибка, что я их неправильно объявляю?

[Vladimir_Der]

Александр, большое спасибо за участие, попробую разобраться с кодом, но пока не работает, спотыкается на строчке

UserForm1.TB4.Text = .Cells(aRowsNr(iCurrRecord), 4), при просмотре выдает значение iCurrRecord=0 (Пробую по Иванову где три записи)

и выдает ошибку out of range

Следующие постоянные
Dim iRecordCount As Integer
Dim iCurrRecord As Integer
Dim aRowsNr() As Integer

я поместил во внутрь блока
Private Sub CommandButton2_Click()

иначе сразу выдавалась ошибка
Может быть в этом и ошибка, что я их неправильно объявляю?

[Aleksandr H.]

Dim iRecordCount As Integer
Dim iCurrRecord As Integer
Dim aRowsNr() As Integer

должны быть глобальными.

https://youtu.be/0wQ-tWtMt80

[Vladimir_Der]

Александр, огромное спасибо! Все работает. Теперь буду знать как объявлять переменные, ранее я не работал с ними.