импорт из txt файлов и их обработка

[evdss]

Здравствуйте. Подскажите пожалуйста как решить данную задачку.
как несколько файлов Txt (данные разделены разделителем #), нах-ся в одной папке открыть на разных листах excel с помощью макроса, а наименования листов совпадали с наименованиями файлов.

[VictorM]

Один из вариантов Сбор данных из множества текстовых файлов с разделителями

[SAS888]

Другой вариант - выполнить макрос:

Sub Main()
    Dim ws As Worksheet, myPath As String, myName As String, s As String, a, fso, ts
    Application.ScreenUpdating = False: Set fso = CreateObject("Scripting.FileSystemObject")
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "Укажите папку c txt-файлами": .Show
        If .SelectedItems.Count = 0 Then Exit Sub
        myPath = .SelectedItems(1) & "\"
    End With
    myName = Dir(myPath & "*.txt"): Set ws = ActiveSheet
    Do While myName <> ""
        Set ts = fso.OpenTextFile(myName, 1)
        a = Split(Application.Clean(ts.ReadAll), "#")
        Sheets.Add.Name = fso.GetBaseName(myName)
        Range([A1], Cells(UBound(a) + 1, 1)).Value = Application.Transpose(a)
        ts.Close: myName = Dir
    Loop: ws.Activate
End Sub

Пример использования во вложении. Будут обработаны все txt-файлы в указанной папке.

[evdss]

Спасибо большое. Только выводиться все в один столбец, а надо текст чтобы распределился по столбцам.

[SAS888]

...выводиться все в один столбец, а надо текст чтобы распределился по столбцам

Т.е. это я сам должен был угадать?
Выводится все в 1 столбец. Строки разделены символом "#".
Будет пример txt-файла и листа Excel с тем, что должно быть в результате - тогда (и только тогда) будет точный ответ.

[tae1980]

Сообщение от evdss

Спасибо большое. Только выводиться все в один столбец, а надо текст чтобы распределился по столбцам.

Я бы воспользовался для этих целей комбинацией из функций word, words, Replace.
Например: строка "111 111#222 222#333 333"
Тогда при выполнении кода:

Sub eee()
Dim a As String
a = "111 111#222 222#333 333"
s = Replace(word(Replace(Replace(a, " ", "`"), "#", " "), 2), "`", " ")
End Sub

Получаем в перемененную s="222 222". Все это можно свернуть в функцию.

Ну а дальше все зависит от фантазии.

'' *** Words ***
'Определяет количество слов в строковой перемнной.
'Аналог команды Rexx.

'На входе:
'str           - Строковая перменная.

'На выходе:
'words         - Количество слов в переменной.

Function words(str) As Long
    
    words = UBound(Split(Application.Trim(Replace(str, vbTab, " ")), " ")) + 1
End Function

'' *** Word ***
'Функция возвращает n-ное слово в указаной строке.
'Аналог команды Rexx.

'На входе:
'str           - Строковая перменная.
'Number        - Номер слова.

'На выходе:
'word          - n-ное слово или пустую строку если слова с таким номером нет.

Function word(str, Number) As String
    On Error Resume Next
    word = Split(Application.Trim(Replace(str, vbTab, " ")), " ")(Number - 1)
End Function

[SAS888]

Если предположить (это я опять гадаю), что есть txt-файл в несколько строк, где в каждой строке есть какие-то данные, разделенные символом "#", и требуется получить листы с именами, совпадающими с именами txt-файлов, в которых данные разделены по строкам также, как и в текстовом файле, а каждая строка этого файла разделена по столбцам, с разделителем "#", то макрос будет таким:

Sub Main()
    Dim i As Long, ws As Worksheet, myPath As String, myName As String, s As String, a, b, fso, ts
    Application.ScreenUpdating = False: Set fso = CreateObject("Scripting.FileSystemObject")
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "Укажите папку c txt-файлами": .Show
        If .SelectedItems.Count = 0 Then Exit Sub
        myPath = .SelectedItems(1) & "\"
    End With
    myName = Dir(myPath & "*.txt"): Set ws = ActiveSheet
    Do While myName <> ""
        Set ts = fso.OpenTextFile(myName, 1)
        Sheets.Add.Name = fso.GetBaseName(myName)
        b = Split(ts.ReadAll, Chr(10))
        For i = LBound(b) To UBound(b)
            a = Split(Application.Clean(b(i)), "#")
            If UBound(a) >= 0 Then Range(Cells(i + 1, 1), Cells(i + 1, UBound(a) + 1)).Value = a
        Next: ts.Close: myName = Dir
    Loop: ws.Activate
End Sub

Пример во вложении.

[evdss]

извините за некорректную формулировку, но это именно то, что мне нужно было. спасибо!!!