открытие файла csv в excel

[Luchiya]

Необходимо открыть файл csv с разделителями ";" в excel. Также открытый файл необходимо присвоить переменной для дальнейшей работы с 2мя разными книгами.
Пишу код:

Sub RBTAdd()

Dim mainwb, wb As Workbook
With Application

ChDir ("C:\ReportSystem\reports\")
NumFiles = .GetOpenFilename("CSV Files (*.csv), *.csv", , "Выбрать файлы для добавления, ,True)
If Not IsArray(NumFiles) Then End

Set mainwb = ActiveWorkbook
.ScreenUpdating = False
stbar = .DisplayStatusBar
.DisplayStatusBar = True

Set wb = Workbooks.OpenText(Filename:=NumFil es(1), DataType:=xlDelimited, _
TextQualifier:=xlTextQualifierNone, FieldInfo:=Array(1, 4), Local:=True)

.......
VBA ругается на OpenText: "Ожидается функция или аргумент". В чем причина, может, кто подскажет?

[EducatedFool]

Для выбора файла можно использовать эту функцию: http://excelvba.ru/code/GetFileOrFolderPath

Код будет выглядеть примерно так:

Sub RBTAdd()
    ' запрашиваем имя файла
    ИмяФайла = GetFileName("Выберите файл CSV", "C:\ReportSystem\reports\", "Отчёты (*.csv*),")
    If ИмяФайла = "" Then Exit Sub    ' выход, если пользователь отказался от выбора файла

    Dim mainwb As Workbook, wb As Workbook

    Set mainwb = ActiveWorkbook
    Application.ScreenUpdating = False
    stbar = Application.DisplayStatusBar
    Application.DisplayStatusBar = True

    Set wb = Workbooks.OpenText(ИмяФайла)
    ' ...
End Sub

Function GetFileName(Optional ByVal Title As String = "Выберите файл для обработки", _
                     Optional ByVal InitialPath, _
                     Optional ByVal MyFilter As String = "Книги Excel (*.xls*),") As String
    ' функция выводит диалоговое окно выбора папки с заголовком Title,
    ' начиная обзор диска с папки InitialPath
    ' возвращает полный путь к выбранной папке, или пустую строку в случае отказа от выбора
    If Not IsMissing(InitialPath) Then
        On Error Resume Next: ChDrive Left(InitialPath, 1)
        ChDir InitialPath    ' выбираем стартовую папку
    End If
    res = Application.GetOpenFilename(MyFilter, , Title, "Открыть")  ' вывод диалогового окна
    GetFileName = IIf(VarType(res) = vbBoolean, "", res)    ' пустая строка при отказе от выбора
End Function

[Luchiya]

все равно ругается на OpenText Expected Function or variable

[EducatedFool]

Сразу как-то не обратил на это внимания...
OpenText - это МЕТОД, а не ФУНКЦИЯ.
Т.е. этот метод просто открывает файл, и не возвращает ссылки на открытый файл
(в отличие от функции workbooks.Open, которая возвращает ссылку на открытый файл)

Правильно будет так:

    Workbooks.OpenText ИмяФайла
    Set wb = ActiveWorkbook

[Luchiya]

о, теперь заработало. спасибо.