Поиск кодом

[Keshunya]

Здравствуйте, уважаемые программисты. Прошу помочь мне в поиске договора. Нужно через код осуществить поиск, проблема вот в чем: Если договора нет, должен ответить "договор не найден", если договор есть, ответ: "договор найден". Как с помощью кода поставить условие. Крутила, мудрила, искала решение, вот что вышло:
Sub Поиск_договора()
Dim Sales
Sales = InputBox(Prompt:="Введите номер договора")
If Sales = "" Then Exit Sub
ActiveSheet.Select
On Error Resume Next
If Cells.Find(What:=Sales) Then
Cells.Find(What:=Sales).Activate
MsgBox "Договор найден"
Else
MsgBox "Нет такого договора"
End If
End Sub
Как мне присвоить условие переменной, чтобы правильно реагировал на запрос? Спасибо вам, дорогие, что не обходите вниманием!

[Hugo121]

Такой вариант. Активацию листа убрал - кнопка и так на нём, код тоже в нём...

Sub Поиск_договора()
        Dim Sales, x As Range
 Sales = InputBox(Prompt:="Введите номер договора")
If Sales = "" Then Exit Sub
Set x = Cells.Find(What:=Sales)
If Not x Is Nothing Then
x.Activate
MsgBox "Договор найден"
Else
MsgBox "Нет такого договора"
End If

End Sub

[Keshunya]

Спасибо огромное! Вот с иксом не совсем понятно, попробую разобраться. Но ведь работает! Супер просто!

[Hugo121]

Да что там - иксу присваивается ссылка на найденную ячейку. Если присвоилось - значит нашли, если всё ещё Nothing - значит нет.

[Djeki]

Сообщение от Hugo121

Такой вариант. Активацию листа убрал - кнопка и так на нём, код тоже в нём...

Sub Поиск_договора()
        Dim Sales, x As Range
 Sales = InputBox(Prompt:="Введите номер договора")
If Sales = "" Then Exit Sub
Set x = Cells.Find(What:=Sales)
If Not x Is Nothing Then
x.Activate
MsgBox "Договор найден"
Else
MsgBox "Нет такого договора"
End If

End Sub

Подскажите пожалуста как продолжить поиск по столбцам В и С до конца этого диапазона "В:С" ?? Т.е. номер договора может встречать несколько раз и надо их все найти. Спасибо за ответ..

[Hugo121]

Это посложнее, сейчас некогда код сочинять... Помогайте
Но сделать можно, через FindNext и Msgbox с vbYesNoCancel + vbQuestion

Пример:

            Select Case MsgBox("Удалить имя диапазона:" & vbCrLf & vbCrLf _
                               & nM.Name & nM.RefersTo, vbYesNoCancel + vbQuestion)
               Case vbYes: nM.Delete
               Case vbCancel: Exit Sub
            End Select

[Hugo121]

Ну вот, вроде скомпоновал

Sub Поиск_договора()
        Dim Sales, x As Range
 Sales = InputBox(Prompt:="Введите номер договора")
If Sales = "" Then Exit Sub
Set x = Cells.Find(What:=Sales)
If Not x Is Nothing Then
Do
x.Activate
            
            Select Case MsgBox("Договор найден." & vbCrLf & "Годится - " _
                               & x.Address & " ?", vbYesNoCancel + vbQuestion)
               Case vbYes: x.Activate: Exit Do
               Case vbCancel: [c2].Activate: Exit Sub
            End Select

Set x = Cells.FindNext(After:=x)
Loop While Not x Is Nothing
Else
MsgBox "Нет такого договора"
End If

End Sub

Хотя в данном случае While Not x Is Nothing лишнее, можно закомментировать

Loop ' While Not x Is Nothing