добавление надстройки в список подключенных

[Bape}l{ka]

добрый вечер))

подскажите пожалуйста, как программно прописать, чтобы надстройка добавлялась в список подключенных.. у меня выдает ошибку, не соображу, как правильно Т_Т

Sub ДобавлениеНадстройки()
   ' проверяем наличие файла в списке подключенных надстроек,
   ' и, если находим его в этом списке, - отключаем надстройку
   ' потом подключаем ее заново
   ActiveWorkbook.IsAddin = True 'скрыть листы файла
   Dim AI As AddIn
    For Each AI In Application.AddIns    ' перебираем все надстройки
       If AI.Name = ThisWorkbook.Name Then AI.Installed = False
    Next AI
    AddIns("CommandBar").Installed = True 'ОШИБКА
    'ActiveWorkbook.IsAddin = False 'показать листы файла
End Sub

[IgorGO]

а с чего Вы взяли, что среди надстроек есть надстройка с имененм CommandBar???
ее нет в коллекции - вот и ошибка.

[EducatedFool]

А обязательно подключать надстройку?
Может, достаточно добавить надстройку в автозагрузку Excel?

[Bape}l{ka]

IgorGO, т.е. получается, что так подключаются только надстройки, которые есть в списке по умолчанию? те которые мы через "обзор" ищем в других папках, надо сначала собственно найти?

AddIns("CommandBar").Installed = True

EducatedFool, возможно и правда легче добавить файл в автозагрузку эксель.
признаться, я думала ,что подключение надстройки это тоже самое, что добавление ее в автозагрузку =ь

[Bape}l{ka]

не совсем в тему...
если у меня есть несколько макросов в разных книгах и я хочу из них создать общую автоподгружаемую надстройку. можно ли их так и оставить в разных книгах?? не перепутаются ли надстройки, создаваемые каждой книгой, когда будут подгружаться к открываемому эксель-документу??

[EducatedFool]

если у меня есть несколько макросов в разных книгах и я хочу из них создать общую автоподгружаемую надстройку. можно ли их так и оставить в разных книгах??

В более понятной терминологии, ваш вопрос звучит примерно так:

У меня есть в банке зеленый горошек, в мешке в шкафу - лук, в холодильнике - майонез.
Могу ли я из них сделать салат, но чтобы все продукты остались на своих местах?
(майонез - в холодильнике, лук - в мешке, и т.д.)

И как нам на него ответить?

[Hugo121]

Игорь, а когда мы смотрим фильм online (или по ТВ) - его убывает в "холодильнике"?
Кстати, что говорит ACTA об online просмотре?
Я думаю, что можно сделать и так - но стОит ли это работы по реализации такой штуки?

[Skif-F]

Я для своих надстроек использую такой вариант - самоустановка надстройки. Например, запускаю файл "SetUp Надстройка.xlam", и файл копирует себя в каталог, где лежат надстройки, но уже под именем "Надстройка.xlam", и подключает себя в надстройки.
Следующий код я размещаю в модуле "ЭтаКнига"

Private Const ThisName = "Надстройка.xlam"  'Под этим именем надстройка будет подключена

Private Sub Workbook_Open()
    Application.ScreenUpdating = False
    Install     'Устанавливаем надстройку
    Application.ScreenUpdating = True
End Sub

Private Sub Install()   'Устанавливаем надстройку
    Dim ad As AddIn, UserLibraryPath As String, TWB As Workbook, MyName As String
    Dim FN As String, MBR As VbMsgBoxResult, fso, Flag As Boolean, Wb As Workbook
    
    Set fso = CreateObject("Scripting.FileSystemObject")  'Объект для работы с файлами

    Set TWB = ThisWorkbook
    FN = TWB.FullName
    MyName = Right(FN, Len(FN) - InStrRev(FN, "\"))  'Выделяем имя из пути
    Flag = False 'Флаг, сигнлизирующий, что такая надстройка была
    For Each ad In Application.AddIns   'Перебираем надстройки
        If ad.Name = ThisName Then      'Если имя надстройки совпадает с нашим
            If ad.FullName = TWB.FullName Then Exit Sub 'Проверяем, "не мы ли это"
            'Если не мы, то советуемся с пользователем:
            MBR = MsgBox("Надстройка " + ThisName + " существует. Заменить?", vbYesNo, "Внимание!")
            If MBR = vbNo Then Exit Sub 'Если заменять не надо
            ad.Installed = False        'Отключаем
            Flag = True                 'Сигналим, что такая надстройка была
            On Error Resume Next  'Включаем обработку ошибок
                Kill ad.FullName            'Удаляем файл
            On Error GoTo 0         'Отключаем обработку ошибок
            Exit For
        End If
    Next ad
    UserLibraryPath = Application.AddIns.Parent.UserLibraryPath 'Путь до надстроек
    On Error Resume Next  'Включаем обработку ошибок
    fso.CopyFile TWB.FullName, UserLibraryPath + ThisName, True 'Копируем свой файл
    On Error GoTo 0         'Отключаем обработку ошибок
    Set Wb = Workbooks.Add
    If Not Flag Then
        Set ad = AddIns.Add(Filename:=UserLibraryPath & ThisName, CopyFile:=True) 'Если такой надстройки не было, подключаем её
    End If
    ad.Installed = True         'Включаем свою надстройку
    Wb.Close False  'После установки, закрываем текущую книгу
End Sub

[Bape}l{ka]

Skif-F, это наверно тот вариант, который мне подойдет больше всего, спасибо))