Запуск макроса из формы

[tgm]

Добрый день. Есть такой макрос:

Sub Макрос1()
Application.ScreenUpdating = False
r = Cells(Rows.Count, 2).End(xlUp).Row
For i = 4 To r
Sheets("Данные").Cells(i, 1).Value = "x"
Sheets("Бланк").Copy After:=Sheets("Бланк")
Cells.Select
Selection.Copy
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Application.CutCopyMode = False
ActiveSheet.Name = Sheets("Данные").Cells(i, 2)
Sheets("Данные").Cells(i, 1).Value = "х"
Next i
Sheets("Данные").Select
Application.ScreenUpdating = True
End Sub
Макрос формирует бланки,беря данные из таблицы на листе"Данные".
На данный момент он запускается из листа "Данные",хотелось бы запускать его из формы,но при работе макроса он выдает ошибку "1004" и выделяет строку
ActiveSheet.Name = Sheets("Данные").Cells(i, 2)
При запуске из других листов тоже не срабатывает...
Помогите пожалуйста довести до ума.

[Hugo121]

У меня и из формы один раз отработал.
На второй раз ругнулся на эту строку, ибо такое имя уже есть.
Если запускать из формы, нужно указать, чьи это cells:

r = Cells(Rows.Count, 2).End(xlUp).Row

Ну и ещё есть что исправить, например

Cells.Select
Selection.Copy
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
Application.CutCopyMode = False

можно заменить на

ActiveSheet.UsedRange.Value = ActiveSheet.UsedRange.Value

Вроде так в итоге получается:

Private Sub CommandButton1_Click()
Application.ScreenUpdating = False
With Sheets("Данные")
r = .Cells(.Rows.Count, 2).End(xlUp).Row
For i = 4 To r
.Cells(i, 1).Value = "x"
Sheets("Бланк").Copy After:=Sheets("Бланк")
ActiveSheet.UsedRange.Value = ActiveSheet.UsedRange.Value
ActiveSheet.Name = .Cells(i, 2)
.Cells(i, 1).Value = "х"
Next i
.Select
End With
Application.ScreenUpdating = True
End Sub

[tgm]

А ведь заработало.. Спасибо большое!