Подсчет и вывод результата...

[sew960i]

Знач так... Есть таблица... В ней есть столбцы, которые в ручную заполняются...
Они имеют вид типа: 6,5,8,4,8,8,5,2,-7,-4,
В результате общее количество подсчета должно вывести в итог формулой...
---------------------------------------------------
например есть
4,5,5,7, и -4,-5,8,
должно вывести
5,7,8,
Вообщем нужно подсчитать приход/расход...
Т.е если есть 2 и -2 то они взаимо уничтожаются...
---------------------------------------------------
Пример можно посмотреть на скрине...

---------------------------------------------------
Помогите пожалуйста!

[Teslenko_EA]

Здравствуйте sew960i.
если допускается применение пользовательских функций, сумму чисел ячейки разделенных запятой, можно получить подобной:

Function sumCount(s) As Long
Dim sArr() As String, i%
If Len(s) > 0 Then
    sArr = Split(s, ",")
    For i = 0 To UBound(sArr)
        If Not Val(sArr(i)) = 0 Then sumCount = sumCount + CDbl((sArr(i)))
    Next
End If
End Function

применяться будет так: =sumCount(D2)
Евгений.

[javvva]

вряд ли тут подойдут суммы.

[sew960i]

Спасибо. Но вы не совсем правильно поняли мой вопрос...
Мне нужно найти не сумму а результат пересчета, как показано на изображении выше...
Пересчет значений под датами и вывод результата в "Итого"...
Например:
--------------------------------------------------------
12.01.2010 | 13.01.2010 | Итого
4,-6,9,8,7, | 3,-4,7,6,2, | 2,3,7,7,8,
--------------------------------------------------------
И к тому же желательно чтоб в итоге вывелось число в порядке возрастания...

[doober]

Это реальная таблица,или задание от студентов.
Очень смахивает на поиск алгоритма.
А свои какие соображения по этому вопросу

[sew960i]

Это реальная таблица.

[EducatedFool]

Алгоритм оказался непростым....

Проверяйте:




Обратите внимание на формулы (применена пользовательская функция)

  Ячейка: G1      Формула  (стиль A1):   =Остаток(A1:F1)
                  Формула  (стиль R1C1): =Остаток(RC[-6]:RC[-1])

Вот весь код:

Function Остаток(ByRef ra As Range) As String
    Dim cell As Range, t As String, n As String, txt As String
    For Each cell In ra.Cells: txt = txt & cell.Text & ",": Next cell
    txt = Replace(txt, ",,", ","): txt = Replace(txt, " ", "")
    arr = Split(txt, ",")
    For i = LBound(arr) To UBound(arr)
        t = arr(i)
        If Len(t) Then
            n = "-" & t: n = Replace(n, "--", "")
            For j = i + 1 To UBound(arr)
                If arr(j) = n Then arr(i) = "": arr(j) = "": Exit For
            Next j
        End If
    Next i
    MyQuickSort arr: txt = Join(arr, ",")
    txt = Replace(txt, ",", " "): txt = Application.Trim(txt) & " "
    Остаток = Replace(txt, " ", ",")
End Function

Sub MyQuickSort(arr, Optional First As Long = -1, Optional Last As Long = -1)
    On Error Resume Next    ' Быстрая сортировка, [Q]uick [S]ort
    Dim i As Long, j As Long, MidEl As Variant, t As Variant
    First = IIf(First = -1, LBound(arr), First)
    Last = IIf(Last = -1, UBound(arr), Last)
    i = First: j = Last: MidEl = arr((First + Last) \ 2)
    Do While i <= j
        If arr(i) < MidEl Then
            i = i + 1
        Else
            If arr(j) > MidEl Then
                j = j - 1
            Else
                t = arr(i): arr(i) = arr(j): arr(j) = t: i = i + 1: j = j - 1
            End If
        End If
    Loop
    If First < j Then Call MyQuickSort(arr, First, j)
    If i < Last Then Call MyQuickSort(arr, i, Last)
End Sub

[sew960i]

БОЛЬШОЕ СПАСИБО!!! РАБОТАЕТ!!!

[sew960i]

А как сделать так же, только чтоб числа сортировались в таком порядке:
8,9,0,1,2,3,4,5,6,7,

[EducatedFool]

Сообщение от sew960i

А как сделать так же, только чтоб числа сортировались в таком порядке:
8,9,0,1,2,3,4,5,6,7,

А что это за порядок такой?
На словах объясните, по какому принципу мы получаем такую последовательность при "сортировке"