Сравнение данных в 2ух столбцах и копирование строк

[vwmexanik]

Здравствуйте Уважаемые!
Вот решил обратится к Вам на форум за помощью, т.к. сам я не программист, но задачу как-то надо решить:
Вообщем есть таблица с 12ю столбцами ABCDEFGHIJKL. В столбцах A и E содержатся данные вида XX1234567, где XX буквы Кириллицы, ну а 1234567 - 7 цифр соответственно
Возможно ли с помощью макроса, наверное, "заставить" программу произвести сверку значений в столбцах A и E и в случае если значения совпадут, скопировать строку со всеми столбцами на "лист2"?
Единственная загвоздка: в столбце E около 35 тыс значений, в столбце А около 15 тыс
Заранее премного благодарен.
С Уважением.

[EducatedFool]

Возможно ли с помощью макроса...

Конечно, возможно.
От Вас - пример файла.

Можно попробовать обойтись и без макросов - используйте формулы, и расширенный фильтр.

произвести сверку значений в столбцах A и E и в случае если значения совпадут

Правильно я понял, что копировать строку надо только в том случае, если значение в столбце А совпадает со значением в столбце Е той же строки?
Или достаточно, чтобы значение из столбца А просто присутствовало в одной из строк в столбце Е?

[doober]

Если не трудно,выложите файлик хотя бы с десятком строк записей

Возможно ли с помощью макроса, наверное, "заставить" программу произвести сверку значений в столбцах A и E и в случае если значения совпадут, скопировать строку со всеми столбцами на "лист2"?

Какую строку по столбцу А или Е скопировать?
Значения уникальные в столбцах,или могут повторяться?

PS.Видите vwmexanik ,а я понял задачу немного по другому

[vwmexanik]

Вот пример:
http://www.sendspace.com/file/ylohnu

Правильно я понял, что копировать строку надо только в том случае, если значение в столбце А совпадает со значением в столбце Е той же строки?
Или достаточно, чтобы значение из столбца А просто присутствовало в одной из строк в столбце Е?

Вот как раз второе...
Вот просто что это: Столбцы BCDEFGHIJKL это данные вытянутые и некой БД. У нас есть номера (столбец А) которые надо сверить с данными из БД, и при совпадении номеров скопировать строку с данными из БД, и совпавшим номеров, т.е. все 12 столбцов

Какую строку по столбцу А или Е скопировать?

По столбцу E наверное, строки в столбцах BCDEFGHIJKL не должны перепутаться

[Pretorianec79]

вот простой макрос, который решает твою задачу, можно его еще модифицировать и навернуть при желании

[doober]

 Sub Sverka()
 Application.ScreenUpdating = False
 
Dim r As Range
Dim f
Dim n, l, k As Long
k=0
 f = Sheets("Лист1").UsedRange.Columns(1).Value
 For n = 1 To UBound(f)
  If f(n, 1) <> "" Then
 Set r = Sheets("Лист1").UsedRange.Columns(5).Find(f(n, 1))
 If Not r Is Nothing Then
 k = k + 1
 l = r.Row
 Sheets("Лист1").Range("A" & l & ":L" & l).Copy Sheets("Лист2").Cells(k, 1)
 End If: End If: Next
  Application.ScreenUpdating = True
End Sub

Я думаю при 30 тыс записей этот будет намного шустрее

[EducatedFool]

Вот ещё более быстрый вариант:

Sub test()
    On Error Resume Next: Application.ScreenUpdating = False
    Dim sh2 As Worksheet: Set sh2 = Worksheets(2)
    sh2.UsedRange.Clear ' очистка листа от прежних данных
    Dim cell As Range, ra As Range, ForCopy As Range
    
    ' перебираем все заполненные ячейки в столбце Е
    Set ra = Range([e1], Range("e" & Rows.Count).End(xlUp)).SpecialCells(xlCellTypeConstants)
    
    For Each cell In ra.Cells
        If Not Range("a:a").Find(cell) Is Nothing Then ' если аналогичный номер есть в столбце А
            If ForCopy Is Nothing Then Set ForCopy = cell Else Set ForCopy = Union(ForCopy, cell)
            If ForCopy.Cells.Count > 1000 Then
                ForCopy.EntireRow.Copy sh2.Range("a" & sh2.Rows.Count).End(xlUp).Offset(1)
                Set ForCopy = Nothing
            End If
        End If
    Next cell
    ForCopy.EntireRow.Copy sh2.Range("a" & sh2.Rows.Count).End(xlUp).Offset(1)
    sh2.UsedRange.EntireColumn.AutoFit: sh2.Rows(1).Delete
    sh2.Activate
End Sub

Пример файла:

[vwmexanik]

doober
EducatedFool
Работает! Даже и не знаю как Вас благодарить! Просто СПАСИБО!!!
Сегодня вечером или завтра опробую на полном списке и доложу.
Еще раз СПАСИБО!

[xamillion]

ребят!!? а может посоветуете гибкое хорошее готовое решение с подобной возможностью или может сами когда уже аписали что-то подобное наверняка, где можно выбирать признак по которому производится стыковка и стыкуемые столбцы (в буквенном и цифровом выражении - или указать какие по счету столбцы или по их буквенным обозначениям)... перекачал более 2-х десятков программ, надстроек и макросов - и ни один не отличался удобством...

[doober]

Не знаю,что и сказать.
Я привык к цифровому обозначению,мне так удобно.
В основном мне приходиться выводить данные из DataSet ов в файлы Excel.