Замена ВПР2

[strannick]

Добрый день, уважаемые форумчане!
Очень нужная формула VLOOKUP2, но тормозит жутко. Перерыл поиск, понял, что многие сталкивались с аналогичной проблемой, но ничего путного не нашлось. Подскажите, чем можно заменить. Или код самой формулы у меня не совсем правильный?

Function VLOOKUP2(Table As Range, SearchColumnNum As Integer, SearchValue As Variant, _
n As Integer, ResultColumnNum As Integer)
Dim i As Integer
Dim iCount As Integer

For i = 1 To Table.Rows.Count
If Table.Cells(i, SearchColumnNum) = SearchValue Then
iCount = iCount + 1
End If
If iCount = n Then
VLOOKUP2 = Table.Cells(i, ResultColumnNum)
Exit For
End If
Next i
End Function

[The_Prist]

По идее так должно быть пошустрее:

Function VLOOKUP2(Table As Range, SearchColumnNum As Integer, SearchValue As Variant, _
                n As Integer, ResultColumnNum As Integer)
    Dim i As Long, iCount As Long
    Dim avArr
    avArr = Table.Value
    For i = 1 To UBound(avArr, 1)
        If avArr(i, SearchColumnNum) = SearchValue Then
            iCount = iCount + 1
        End If
        If iCount = n Then
            VLOOKUP2 = avArr(i, ResultColumnNum)
            Exit For
        End If
    Next i
End Function

[strannick]

Ого!!! Суперам большой привет и огромное спасибо! Буду пробовать. Но, честно говоря, не первый раз сталкиваюсь с такой заторможенностью ВПР2. А в принципе, чем можно заменить? Какая другая функция (не макрос) может выполнять те же задачи?

[The_Prist]

В принципе, без макросов можно заменить формулой массива(ввод завершается нажатием не просто Enter, а Ctrl+Shift+Enter. Формула при этом будет заключена в фигурные скобки - {} ):

=ИНДЕКС(A1:B5;НАИМЕНЬШИЙ(ЕСЛИ(A1:A5="g";СТРОКА(A1:A5));3);2)

Если подставить в неё аргументы из ВПР2(для большего понимания), то получиться вот что:

=ИНДЕКС(Table;НАИМЕНЬШИЙ(ЕСЛИ(Ссылка_на_диапазон_для_поиска_значения=SearchValue;СТРОКА(Ссылка_на_диапазон_для_поиска_значения));n);ResultColumnNum)

Кол-во строк в Ссылка_на_диапазон_для_поиска_значе ния и в Table должно быть одинаковым.