использование пользовательских функций

[Jaroslav]

Всем привет. Ребята, напишите, пожалуйста, подробно как использовать пользовательскии функции (Function) в программах. Например, у меня есть функция DeleteTextInBrackets:

Private Function DeleteTextInBrackets$(iText$)
    Dim iStart%, iLength%
    Do While iText Like "*[[]*]*"
       iStart = InStr(iText, "[")
       iLength = InStr(iStart, iText, "]") - iStart + 1
       iText = Application.Replace(iText, iStart, iLength, "")
    Loop
    DeleteTextInBrackets = iText
End Function

Эта функция удаляет текст, находящийся между двумя парными скобками [ ], включая сами скобки. Как ею пользоваться?

[Hugo121]

Например так:

Sub tt()
    Dim s$
    s = "asdad [njf] dfgd [ete]hfh"
    MsgBox s
    s = DeleteTextInBrackets(s)
    MsgBox s
End Sub

код функции положите где-то там же в модуле (или в другом, если убрать Private).

[Jaroslav]

Спасибо, Hugo121. А можно ли применить функцию, которую я написал, например, к диапазону А1:А10?

[IgorGO]

одна беда при вложенных скобках:
с такой строки
"a[b[c]d]e"
после удаления останется
"ad]e"

Вы на это рассчитывали???
по моим представлениям должно остаться "ae"

[Jaroslav]

IgorGO, конечно нет

[Hugo121]

Можно и к диапазону - на листе как стандартную, или в коде перебирать ячейки и каждую обрабатывать.

[Jaroslav]

применение функции, которую я написал, к диапазону А1:А10:

Sub Испозование_функции()
Dim i As Integer
For i = 1 To 10
    Cells(i, 1) = DeleteTextInBrackets(Cells(i, 1).Value)
Next
End Sub

[IgorGO]

исходная ___Результаты
строка _____Ваша _Эта
"a[b[c]d]e" _"ad]e" _"ae"
"a[b[c]de" __"ade" __"a[bde"

Private Function DeleteTextInBrackets$(iText$)
    Dim iStart%, iEnd%
    If iText Like "*[[]*]*" Then
       iStart = InStr(iText, "[")
       iEnd = InStr(iStart, iText, "]")
       Do While InStr(iStart + 1, iText, "[") > 0 And InStr(iStart + 1, iText, "[") < iEnd
         iStart = InStr(iStart + 1, iText, "[")
       Loop
       iText = DeleteTextInBrackets(Application.Replace(iText, iStart, iEnd - iStart + 1, ""))
    End If
    DeleteTextInBrackets = iText
End Function

[eval]

"a[b[c]de" __"ade" __"a[bde"

а почему не "ade" ?

[IgorGO]

потому что по предложенному алгоритму удаляются сначала внутренние пары скобок (удалились скобки вокруг С, а первая осталась без пары вот и не удалена.

я вообще-то не знаю, что на самом деле нужно удалять автору темы)))