1. Присвоить переменной значение ячейки, находящейся в ТЕКУЩЕМ ряду в столбце "E" 2.Вопрос по автофильтру

[Павел-812]

Здравствуйте!
К вам пара вопросов, если ответите, то очень мне поможете.

Итак, вопрос 1. Выделена произвольная ячейка в какой-то определённой строке таблицы. Как мне присвоить переменной x значение ячейки, располагающейся в ТЕКУЩЕЙ строке, столбце E?


Вопрос 2. В таблице с помощью автофильтра произведена выборка данных, например, по фильтру имеем одну единственную строку:

"Г.Симоняка ул." (ячейка A35), "д.23" (ячейка B35) и "ЖКС1" (ячейка C35)

Как мне присвоить переменной X значение, находящееся в третьей ячейке (в данном случае C35). Проблема в том, что в результате выборки это будет не всегда ячейка C35, а может быть C12, C19, C39 - в общем, всё что угодно.

[EducatedFool]

Sub Вопрос1()
    [f12].Select    ' выделена ячейка F12
    x = ActiveCell.EntireRow.Cells(5)    ' читаем значение 5-й ячейки (столбец E) той же строки
    Debug.Print x
End Sub


Sub Вопрос2()
    Set cell = [c1].End(xlDown) ' равносильно нажатию Ctrl + СтрелкаВниз при выделенной ячейке С1
    ' cell - ячейка, на которую мы попали после нажатия Ctrl + СтрелкаВниз
    
    ' если мы оказались не на последней строке листа, то читаем значение ячейки
    If cell.Row <> Rows.Count Then x = cell.Value
End Sub

[Павел-812]

EducatedFool, огромнейшее Вам спасибо за развёрнутый ответ! Не ожидал так скоро получить квалифицированную помощь! СПА-СИ-БО!

[Павел-812]

Кстати, а как сделать активной ячейку, на которой стоит курсор?? Всё дело в том, что макрос отказывается работать со строкой, в которой находится курсор.

[EducatedFool]

Отписал в личку.

Требовалось что-то вроде этого:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    ' запускается при изменении выделения на листе
    If Target.Cells.Count > 1 Then Exit Sub    ' выход из макроса, если выделено больше одной ячейки

    x = Target.EntireRow.Cells(5)
    y = Target.EntireRow.Cells(6)

    ' результат наблюдаем в строке состояния Excel
    Application.StatusBar = "Значение в столбце E равно  " & x & " ,    в столбце F равно  " & y
End Sub

[whitest]

Доброго дня всем!

Прошу маленькую помощь в решении такой задачки: имеется таблица, в одной из колонок содержится время в формате Unix. Например, вот пару ячеек:
1309454110
1309454212
1309454215
1309454390.
Чтобы перевести его в календарный вид используется формула: =ДАТА(1970;1;1)+ ячейка_с_Unix-временем/86400 .

Беда в том, что в столбце таких ячеек тысяч 40. Вот я попробовал сам че-то наковырять (для отрезка E2-E50), замена работает только для одной ячейки (на которой поставлен курсор), а цикл не получается запустить =(

Sub unix-time()
Dim x As Range
For Each c In Worksheets("Sheet 1").Range("E2:E50").Cells
ActiveCell.FormulaR1C1 = "=DATE(1970,1,1)+ RC[1]/86400"
Selection.NumberFormat = "[$-409]dd/mm/yy h:mm AM/PM;@"
Next c
End Sub

Помоги кто-нить пожалуйста с циклом..

[EducatedFool]

Sub test()
    Dim ra As Range: Application.ScreenUpdating = False
    Set ra = Range([A1], Range("A" & Rows.Count).End(IIf(Len(Range("A" & Rows.Count)), xlDown, xlUp)))
    arr = ra.Value
    For i = LBound(arr) To UBound(arr)
        arr(i, 1) = CDbl(DateSerial(1970, 1, 1)) + arr(i, 1) / 86400
    Next i
    ra.Value = arr
    ra.NumberFormat = "[$-409]dd/mm/yy h:mm AM/PM;@"
End Sub

Пример в файле: http://excelvba.ru/XL_Files/Sample__...__12-32-52.zip