Как сделать сортировку столбца по клику на его заголовок?

[SAS888]

Как вариант, можно для сортировки нажимать на правую кнопку мыши. Тогда код от IgorGO нужно запускать по событию

Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)

А в самом конце кода добавить строку

 Cancel = True

В этом случае можно многократно производить сортировку не деактивируя выбранную ячейку.

[IgorGO]

Прошу прощения за назойливость.

я бы назвал это целеустремленность. Вы высказываете просьбы, личное дело каждого из тех, кому совершенно очевидно как это сделать, сделать это или нет. У меня было время и настроение...

Вы все сделали, почти как мне хотелось.

я сам понимаю что там хорошо, а что сделано кривовато. Это заготовка - тщательно обрабатываете напильником.

чтобы мой файл мог сортироваться по столбцам на любом компе у любого пользователя.

рассылайте пользователям - этот вариант уже довольно плотно приблизился к окончательному продукту.
одна уловка первая счейка таблицы должна обязательно называться "ФИО (начало таблицы)" (фио десять пробелов (начало таблицы)).

[slan]

а по-моему былобы достаточно только одну строчку к первоначальному добавить:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  If Target.Cells.Count > 1 Then Exit Sub
  If Application.Intersect(Target, Range("B8:E8")) Is Nothing Then Exit Sub
  With Sort
    .SortFields.Clear
    .SortFields.Add Key:=Target.Resize(Target.End(xlDown).Row - Target.Row + 1, 1), SortOn:=xlSortOnValues, _
    Order:=IIf(Right(Target, 1) = " ", xlAscending, xlDescending), DataOption:=xlSortNormal
    If Right(Target, 1) = " " Then Target = Trim(Target) Else Target = Target & " "
    .SetRange Target.Offset(0, 2 - Target.Column).Resize(Target.End(xlDown).Row - Target.Row + 1, 4)
    .Header = xlYes
    .Apply
  End With
  Target.Offset(1).Select
End Sub

[DiemonStar]

Сообщение от slan

а по-моему былобы достаточно только одну строчку к первоначальному добавить:

тогда правильнее совместно с еще двумя строчками:

Application.EnableEvents = False
...
Application.EnableEvents = True

зачем еще раз вызывать это же событие?)

[IgorGO]

slan,
попадание 100%. минимум усилий, решение нескольких проблем.

DiemonStar,
это задумка такая автора: раз кликнул - посортировалось в одну сторону, второй - в другую... ляпота!

[DiemonStar]

Сообщение от IgorGO

DiemonStar,
это задумка такая автора: раз кликнул - посортировалось в одну сторону, второй - в другую... ляпота!

Игорь, здесь даже вопрос не стоит. я про другое:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  If Target.Cells.Count > 1 Then Exit Sub
  If Application.Intersect(Target, Range("B8:E8")) Is Nothing Then Exit Sub
  With Sort
    .SortFields.Clear
    .SortFields.Add Key:=Target.Resize(Target.End(xlDown).Row - Target.Row + 1, 1), SortOn:=xlSortOnValues, _
    Order:=IIf(Right(Target, 1) = " ", xlAscending, xlDescending), DataOption:=xlSortNormal
    If Right(Target, 1) = " " Then Target = Trim(Target) Else Target = Target & " "
    .SetRange Target.Offset(0, 2 - Target.Column).Resize(Target.End(xlDown).Row - Target.Row + 1, 4)
    .Header = xlYes
    .Apply
  End With
  Target.Offset(1).Select
End Sub

вот этот код чуть подправить:

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  If Target.Cells.Count > 1 Then Exit Sub
  If Application.Intersect(Target, Range("B8:E8")) Is Nothing Then Exit Sub
  Application.EnableEvents = False
  With Sort
    .SortFields.Clear
    .SortFields.Add Key:=Target.Resize(Target.End(xlDown).Row - Target.Row + 1, 1), SortOn:=xlSortOnValues, _
    Order:=IIf(Right(Target, 1) = " ", xlAscending, xlDescending), DataOption:=xlSortNormal
    If Right(Target, 1) = " " Then Target = Trim(Target) Else Target = Target & " "
    .SetRange Target.Offset(0, 2 - Target.Column).Resize(Target.End(xlDown).Row - Target.Row + 1, 4)
    .Header = xlYes
    .Apply
  End With
  Target.Offset(1).Select
  Application.EnableEvents = True
End Sub

потому как Select в последней строке сформирует рекуррентное событие.

[IgorGO]

да, без Application.EnableEvents = False
Target.Offset(1).Select вызовет
Worksheet_SelectionChange 1 раз, но процедура завершит работу по
If Application.Intersect(Target, Range("B8:E8")) Is Nothing Then Exit Sub
лишний вызов есть, зацикливания нет, потому что отмеченная ячейка теперь под шапкой таблицы, а не в шапке.

[slan]

Сообщение от DiemonStar

тогда правильнее совместно с еще двумя строчками:

Application.EnableEvents = False
...
Application.EnableEvents = True

зачем еще раз вызывать это же событие?)

в принципе да, но в данном случае и так будет нормально ибо к зацикливанию не приведет