Проверка ячеек таблицы на корректность

[Rider-12]

здраствуйте! помогите с такой задачей, когда в таблице находятся данные и нужно проверить эти данные на корректность и добавить заливку на строку диапазона ячеек [A:G], если имеются некорректные данные. В столбцах [A:C] должны стоять только русские буквы, а в столбцах [D:F] только числа. буду очень благодарен!

[SAS888]

А в столбце "G" что допустимо? Пустые значения допустимы? Пробелы, знаки препинания, спец. символы допустимы?

[Rider-12]

Сообщение от SAS888

А в столбце "G" что допустимо? Пустые значения допустимы? Пробелы, знаки препинания, спец. символы допустимы?

там только число, сумма [D:F]

[SAS888]

Если в таблице уже находятся данные и требуется подсветить некорректные ячейки, то можно воспользоваться макросом:

Sub ReColor()
    Dim cell As Range
    For Each cell In Intersect(ActiveSheet.UsedRange, [A:C])
        If LCase(cell) Like "*[!а-я]*" Then cell.Interior.ColorIndex = 6 Else cell.Interior.ColorIndex = xlNone
    Next
    For Each cell In Intersect(ActiveSheet.UsedRange, [D:F])
        If cell Like "*[!0-9]*" Then cell.Interior.ColorIndex = 6 Else cell.Interior.ColorIndex = xlNone
    Next
End Sub

ПРИМЕЧАНИЕ: Т.к. Вы упорно не хотите говорить, что делать с пробелами, точками, запятыми и т.п., то макрос сделан так, что эти символы являются недопустимыми.

P.S. Если же требуется контролировать вводимые значения, то макрос будет другой и его выполнение будет привязано к событию изменения значения ячейки (ячеек) в контролируемых диапазонах.

[Ilya_L]

а если подсветить полностью строки, начиная с 4, а не ячейки?

[SAS888]

Тогда можно так:

Sub ReColor()
    Dim cell As Range: Application.ScreenUpdating = False
    Cells.Interior.ColorIndex = xlNone
    For Each cell In Intersect(ActiveSheet.UsedRange, [A:C], Rows("4:" & Rows.Count))
        If LCase(cell) Like "*[!а-я]*" Then cell.EntireRow.Interior.ColorIndex = 6
    Next
    For Each cell In Intersect(ActiveSheet.UsedRange, [D:F], Rows("4:" & Rows.Count))
        If cell Like "*[!0-9]*" Then cell.EntireRow.Interior.ColorIndex = 6 Else
    Next
End Sub

[Ilya_L]

А для запятой будет выглядеть так If cell Like "*[!,]*" ?

[Ilya_L]

В столбцах D и E должны стоять целые числа, а в F и дробные, и целые, т.е. там должна еще запятая прописываться..

[SAS888]

Нет. Все несколько сложнее. Код

If LCase(cell) Like "*[!а-я]*" Then...

означает, что если в переведенном в нижний регистр (чтобы не проверять отдельно прописные и строчные символы) cell встречается хотя бы 1 символ, не принадлежащий (об этом говорит восклицательный знак) к группе символов [а-я], то условие выполняется. Следовательно, и латинские буквы и запятая и т.д. будут удовлетворять этому условию. Поэтому, при определении вхождения "чужого" символа, лучше всего просто игнорировать те, которые Вас не интересуют. Так, например, для того, чтобы допустить запятую, можно воспользоваться следующим:

Sub ReColor()
    Dim cell As Range: Application.ScreenUpdating = False
    Cells.Interior.ColorIndex = xlNone
    For Each cell In Intersect(ActiveSheet.UsedRange, [A:C], Rows("4:" & Rows.Count))
        If Replace(LCase(cell), ",", "") Like "*[!а-я]*" Then cell.EntireRow.Interior.ColorIndex = 6
    Next
    For Each cell In Intersect(ActiveSheet.UsedRange, [D:F], Rows("4:" & Rows.Count))
        If Replace(cell, ",", "") Like "*[!0-9]*" Then cell.EntireRow.Interior.ColorIndex = 6 Else
    Next
End Sub

P.S. Будьте внимательны. Если формат ячейки определен как числовой с десятичными знаками, то, например, число 23,00 это только отображение числа 23 в определенном Вами формате. На самом же деле, символ "," это значение не содержит.

[Ilya_L]

а я так хотел сделать, чтобы в D и E стобцах были числа без запятых, а в F числа с запятыми или без них (дробные)...но на отдельный столбец она не работает

    Dim cell As Range: Application.ScreenUpdating = False
    Cells.Interior.ColorIndex = xlNone
    For Each cell In Intersect(ActiveSheet.UsedRange, [A:C], Rows("4:" & Rows.Count))
        If LCase(cell) Like "*[!а-я]*" Then cell.EntireRow.Interior.ColorIndex = 6
    Next
    For Each cell In Intersect(ActiveSheet.UsedRange, [D:E], Rows("4:" & Rows.Count))
        If cell Like "*[!0-9]*" Then cell.EntireRow.Interior.ColorIndex = 6
    Next
    For Each cell In Intersect(ActiveSheet.Range, [f], Rows("4:" & Rows.Count))
        If Replace(cell, ",", "") Like "*[!0-9]*" Then cell.EntireRow.Interior.ColorIndex = 6 Else
    Next