тормозит макрос после первой печати данного документа

[SergeiK]

Господа, и Дамы, доброго времени суток! Помогите пожалуйста вот с чем: есть макрос(привязан к кнопке), который скрывает строки, работает как надо, но, после первой печати данного листа нажимаю снова на кнопку макроса, тогда excelевкий файл начинает очень сильно виснуть (примерно секунд на 20). Подскажите пожалуйста, как можно избежать такое торможение. вот код:


Option Explicit
Dim bl As Boolean
Sub sergHid()
Dim r As Range: Application.ScreenUpdating = False
With [b9:b258]
For Each r In .Cells
r.EntireRow.Hidden = r = ""
Next
End With: Application.ScreenUpdating = True
End Sub

забыл сказать, в скрываемых строках есть формулы, но значения пустые.

[nilem]

Посмотрите свою старую тему, там есть второй вариант - немного быстрее.
Хотя и там, и там виснуть особо не из-за чего. Может у Вас в книге есть еще какие-то макросы?

[slan]

вот так может быть чуть быстрее:

Sub sergHid()
Dim i&, x, c&
c = Application.Calculation
Application.ScreenUpdating = False: Application.Calculation = xlCalculationManual
Set x = [b9:b258].Value
x.Rows.Hidden = False
For i = 1 To UBound(x)
If x(i) = "" Then Rows(i + 8).Height = 0
Next
Application.ScreenUpdating = True: Application.Calculation = c
End Sub

[Hugo121]

slan, смутило, проверил, заработало так:

Sub sergHid()
Dim i&, x, c&
c = Application.Calculation
Application.ScreenUpdating = False: Application.Calculation = xlCalculationManual
Set x = [b9:b258]
x.Rows.Hidden = False
Let x = [b9:b258].Value
For i = 1 To UBound(x)
If x(i, 1) = "" Then Rows(i + 8).RowHeight = 0
Next
Application.ScreenUpdating = True: Application.Calculation = c
End Sub

А чуть быстрее так:

Sub sergHid()
Dim i&, x, c&
c = Application.Calculation
Application.ScreenUpdating = False: Application.Calculation = xlCalculationManual
[b9:b258].Rows.Hidden = False
x = [b9:b258].Value
For i = 1 To UBound(x)
If x(i, 1) = "" Then Rows(i + 8).RowHeight = 0
Next
Application.ScreenUpdating = True: Application.Calculation = c
End Sub

[slan]

согласен, второй вариант и имел ввиду..

[Hugo121]

Ну и ещё RowHeight

[SergeiK]

Да есть еще один макрос, на другой вкладке, который преобразовывает в число
вот он:
Sub ïðåîáðàçîâàòüÂ÷èñëî()
For a = 2 To 3000
For b = 1 To 4
If (b <> 8 Or b <> 6 Or b <> 5) Then
Cells(a, b).Value = Val(Cells(a, b).Value)
End If
Next
Next
End Sub

[Hugo121]

Вот это интересно:
For b = 1 To 4
If (b <> 8 Or b <> 6 Or b <> 5) Then



А так - проверяйте перебором массив (Вы ведь вероятно что-то проверить хотели), а потом уже правьте на листе.

[SergeiK]

все, спасибо ребята за помощь! разобрался!

[SergeiK]

Сообщение от Hugo121

Вот это интересно:
For b = 1 To 4
If (b <> 8 Or b <> 6 Or b <> 5) Then



А так - проверяйте перебором массив (Вы ведь вероятно что-то проверить хотели), а потом уже правьте на листе.

так и есть он на листе