Помогите найти ошибку в задании с вектором в VBA

[MorbidGoth]

Добрый день.

Вобщем задача была следующей:
некое тело двигается по клеточкам в excel, натыкается на клеточку с номером, появляется InputBox с заданием, задание нужно выполнить и программа оценит правильный ответ или нет.
1. Найти сумму элементов вектора, которые меньше данного числа
2. Найти сумму нечетных элементов вектора

Программа считает все правильно (я проверяла=), но когда идет оценка результата, то даже на правильный ответ мне пишет Wrong answer.
Никак не могу найти, где ошибка.
Может кто-нибудь сможет помочь?

Вот код

Sub Quests(nr)
Dim result
Const Penalty_amount = 5
    If nr = 1 Then
    result = Translate_eng_to_est()  ' s?na t?lkimine: inglise => eesti, juhuslik valik loendist
    ElseIf nr = 2 Then
    result = vaiksemate_vektorite_summa() ' antud arvust v?iksemate vektori elementide summa
    ElseIf nr = 3 Then
    result = vekt_paaritu_el_sum() 'vektori paarituarvuliste elementide summa
    ElseIf nr = 4 Then
    result = mat_max_el() ' maksimaalne element maatriksi juhuslikus reas
 End If
     If result = -1 Then 'penalty setting
        Range("Penalty") = Range("Penalty") + 4 * Penalty_amount
    ElseIf result = 0 Then
        Range("Penalty") = Range("Penalty") + Penalty_amount
    ElseIf result = 1 Then
        Range("Penalty") = Range("Penalty")
    End If       
End Sub

Function vaiksemate_vektorite_summa() ' сумма элементов вектора, которые меньше данного числа
 Dim answer2
 make_vektor
   answer2 = InputBox("Vaiksemate elementide summa (Vahem kui '5').          '" & Show_vektor & "'  ")
   If answer2 = "" Then
        MsgBox "Empty answer!"
        vaiksemate_vektorite_summa = -1
        ElseIf answer2 <> VVSum Then
        MsgBox "Wrong answer!"
        vaiksemate_vektorite_summa = 0
    ElseIf answer2 = VVSum Then
        MsgBox "Correct!"
        vaiksemate_vektorite_summa = 1
    End If
   End Function

Function vekt_paaritu_el_sum() 'сумма нечетных элементов вектора
Dim answer3
make_vektor
answer3 = InputBox("Vektori paarituarvuliste elementide summa.                  '" & Show_vektor & "'  ")
If answer3 = "" Then
        MsgBox "Empty answer!"
        vekt_paaritu_el_sum = -1
         ElseIf answer3 <> PASum Then
        MsgBox "Wrong answer!"
        vekt_paaritu_el_sum = 0
    ElseIf answer3 = PASum Then
        MsgBox "Correct!"
        vekt_paaritu_el_sum = 1
    End If
End Function

Sub make_vektor() 'создает вектор
     Dim n As Integer
     Dim i As Integer
      n = Rand_num(4, 10)
   ReDim V(1 To n)  
For i = 1 To n
      V(i) = Rand_num(-10, 10)
 Next i  
End Sub

Function Show_vektor()
    Dim i As Integer
    Dim T
    Dim n As Integer    
        n = UBound(V, 1)
        T = V(1)
        For i = 2 To n
            T = T & " , " & V(i)
        Next i
    Show_vektor = T
End Function

Function VVSum() 'сумма векторов, которые меньше данного числа
    Dim i As Integer
    Dim n As Integer    
     n = UBound(V, 1)
        For i = 1 To n
            If V(i) < 5 Then VVSum = VVSum + V(i)
        Next i       
End Function

Function PASum() 'сумма нечетных векторов
   Dim i As Integer
   Dim n As Integer   
   n = UBound(V, 1)
        For i = 1 To n
        If V(i) Mod 2 <> 0 Then PASum = PASum + V(i)
    Next i
End Function

[Aleksandr H.]

Еще бы сам excel файл увидить с этим...

[MorbidGoth]

вот
rada.zip

[Aleksandr H.]

InputBox возвращает значения типа String a VVSum Integer, надо бы преобразовать

answer2 = InputBox("Vaiksemate elementide summa (Vahem kui '5').          '" & Show_vektor & "'  ")

в

answer2 = CInt(InputBox("Vaiksemate elementide summa (Vahem kui '5').          '" & Show_vektor & "'  "))

[MorbidGoth]

Ура!Ура! оно работает))))

спасибо большое))

пойду копать дальше