Импорт картинок из папки в текст WORD 2007 макросом

[hlibhlib]

Здравствуйте, форумчане!!!
Мне надо импортировать все картинки из папки в текст WORD 2007 используя макрос.
Начинаю запись макроса, из *Вставка* выбираю *Вставить рисунок из файла*, указываю папку где лежат .bmp , нажимаю Ctrl+A, Enter и ...
останавливаю запись макроса. А когда хочу воспользоваться этим макросом, то получаю только одну картинку.

Selection.InlineShapes.AddPicture Filename:= _
"C:\Documents and Settings\All Users\Documents\shared Mcamx6\common\reports\IMG\Image #1.bmp" _
, LinkToFile:=False, SaveWithDocument:=True

Подскажите , как заставить импортироваться ВСЕ картинки из папки???

[viter.alex]

Каким образом вставлять? Все подряд друг за другом?

[hlibhlib]

Сообщение от viter.alex

Каким образом вставлять? Все подряд друг за другом?

Здравствуйте, viter.alex.
Картинки находящиеся в папке, имеют названия с номерами очередности их создания.
Расположение их должно быть поочередно сверху вниз по документу и уменьшены в 2-а раза сохраняя пропорцию.

Спасибо за отклик и старание помочь.

Выбираю стандартную функцию - *Вставить рисунок из файла*, потом макросом, кот. нарыл и-нэте, (спасибо выложившему):

Attribute VB_Name = "Module3"
Sub changeImages2()
Dim pic As Object
On Error Resume Next
For Each pic In ActiveDocument.Content.InlineShapes
If pic.Type = wdInlineShapePicture Then
pic.Height = pic.Height / 2
pic.Width = pic.Width / 2
End If
Next
For Each pic In ActiveDocument.Content.ShapeRange
If pic.Type = msoPicture Then
pic.Height = pic.Height / 2
If pic.LockAspectRatio = msoFalse Then
pic.Width = pic.Width / 2
End If
End If
Next
End Sub

Пробовал команды и строки из учебников тыкать, но о результате можно догадаться! Темный лес - да и только!

[viter.alex]

Порядок сортировки зависит от порядка сортировке в окне выбора файлов

Sub InsertPicturesFromFolder()
    'Диалог выбора файлов
    With Application.FileDialog(msoFileDialogFilePicker)
        .AllowMultiSelect = True
        .Title = "Выберите изображения"
        .Filters.Clear
        .Filters.Add "Изображения JPEG", "*.jpeg;*.jpg"
        .Filters.Add "Изображения PNG", "*.png"
        .Filters.Add "Изображения BMP", "*.bmp"
        .Filters.Add "Все изображения", "*.jpeg;*.jpg;*.png;*.bmp"
        .InitialView = msoFileDialogViewProperties
        If .Show Then
            Dim inshp As InlineShape, i As Integer
            For i = 1 To .SelectedItems.Count
                'Вставка изображения
                Set inshp = ActiveDocument.Paragraphs.Last.Range.InlineShapes.AddPicture(.SelectedItems(i), False, True)
                'Фиксация соотношения сторон
                inshp.LockAspectRatio = msoTrue
                'Уменьшаем ширину в два раза (на 50%)
                inshp.ScaleWidth = 50
                'Добавляем ещё один абзац
                ActiveDocument.Paragraphs.Last.Range.InsertParagraphAfter
            Next
        Else
            Exit Sub
        End If
    End With
End Sub

[hlibhlib]

Спасибо.
Подумаю, что можно с этим кодом сделать.
Спасибо.

[hlibhlib]

Нет, не получается.

Очень жаль.

[viter.alex]

Что не получается? Не говорите загадками

[hlibhlib]

CUT; CUT; CUT;

[hlibhlib]

Сообщение от viter.alex

Что не получается? Не говорите загадками

Челобитная в личке.