Регулярные выражения. Для чайника

[Aleksandr H.]

Хочу понять регулярные выражения. Почитал http://stackoverflow.com/questions/2...cell-and-loops
Темный лес
Для обучения я взял таблицу и хочу привести ее к виду, например для первого номер, +38 (067) 111 22 33

(067)1112233
(044)*111-22-33
(0332)123456, 123457
(048)1234567, 123456
(0342)122156
+38 (0522) 12-43-56
0372-123456
(0512)654321
(066)1234567;(067)1234567
+38 (050) 111-22-33
773332211
(067)5556677 (067)9998877

Подскажите как решаются такие задания?

Для первой записи решил что pattern должен быть
"( [(] [0-9]{3} [)]) ([0-9]{3}) ([0-9]{2}) ([0-9]{2})"

Private Sub simpleRegex()
    Dim strPattern As String: strPattern = "([(][0-9]{3}[)])([0-9]{3})([0-9]{2})([0-9]{2})"
    Dim RegEx      As VBScript_RegExp_55.RegExp
    Dim strInput As String
    Dim Myrange As Range
    Dim cell
    Set Myrange = ActiveSheet.Range("A2:A28")
    Set RegEx = New VBScript_RegExp_55.RegExp
    For Each cell In Myrange
        If strPattern <> "" Then
            strInput = Replace(cell.Value, " ", "")
            With RegEx
                .Global = True
                .MultiLine = True
                .IgnoreCase = False
                .Pattern = strPattern
            End With

            If RegEx.Test(strInput) Then
                cell.Offset(0, 1) = RegEx.Replace(strInput, "+38 $1 $2 $3 $4")
            End If
        End If
    Next
End Sub

Сработало, но почему также обработались строки

(048)1234567, 123456 => +38 (048) 123 45 67,123456
(066)1234567;(067)1234567 => +38 (066) 123 45 67;+38 (067) 123 45 67
(067)5556677 (067)9998877 => +38 (067) 555 66 77+38 (067) 999 88 77

?

Вообщем, прошу подтолкнуть алгоритмом и в синтаксисе регулярных выражений.

[EducatedFool]

с такими данными, где может быть несколько номеров в строке (через запятую, через точку с запятой, или вообще без разделителя), где второй и последующий номера могут быть в кратком формате (без кода города), - регуляркой одной лишь никак не справиться

сначала макрос, который приведет все данные в нормальный формат (все номера с одним количеством цифр, через единый разделитель),
а потом скобочки и пробелы и префикс добавить, - это легко (хоть регуляркой, хоть форматом числа, хоть простыми функциями VBA)

Но, начинать в любом случае надо с макроса, который уберет все лишние символы, допишет коды городов к тем номерам, где их нет, все разделители (запятые) между номерами проставит

[IgorGO]

написание масок - это практически язык программирования
синтаксис простой, но нужно практиковаться...
чем разношерстнее данные - тем сложнее придумать универсальную маску под них

Удачи!

[svsh2016]

добрый вечер,попробовал,Вам помочь в виде трех версий,чтобы Вам было легче проследить процесс улучшения макроса,полностью доделывать не стал ,если Вас интересует могу доделать,в соответствии с разумными замечаниями предыдущих участников обсуждения.

Sub simpleRegex()
    Dim RegEx As Object
    Dim strInput As String
    Dim Myrange As Range
    Dim cell As Range
    Set Myrange = ActiveSheet.Range("A1:A28")
    Set RegEx = CreateObject("VBScript.RegExp"): RegEx.Global = True
    RegEx.Pattern = "([(][0-9]{3}[)])([0-9]{3})([0-9]{2})([0-9]{2})"
    For Each cell In Myrange
            strInput = Replace(cell.Value, " ", "")
            If RegEx.Test(strInput) Then
                cell.Offset(0, 1) = RegEx.Replace(strInput, "+38 $1 $2 $3 $4")
            End If
    Next
End Sub

затем вывод данных правее

Sub simpleRegex1()
    Dim RegEx As Object
    Dim strInput As String
    Dim Myrange As Range
    Dim cell As Range
    Set Myrange = ActiveSheet.Range("A1:A28")
    Set RegEx = CreateObject("VBScript.RegExp"): RegEx.Global = True
    RegEx.Pattern = "(\(\d{3}\))(\d{3})(\d{2})(\d{2})"
    For Each cell In Myrange
            strInput = Replace(cell.Value, " ", "")
            If RegEx.Test(strInput) Then
                cell.Offset(0, 3) = RegEx.Replace(strInput, "+38 $1 $2 $3 $4")
            End If
    Next
End Sub

Затем вывод данных еще правее

Sub simpleRegex2()
      Dim strInput$, Myrange As Range, cell As Range
    Set Myrange = ActiveSheet.Range("A1:A28")
    With CreateObject("VBScript.RegExp"): .Global = True: .Pattern = "(\(\d{3}\))(\d{3})(\d{2})(\d{2})"
       For Each cell In Myrange
            strInput = Replace(cell.Value, " ", "")
            If .Test(strInput) Then cell.Offset(0, 6) = .Replace(strInput, "+38 $1 $2 $3 $4")
       Next
    End With
End Sub

Отсюда видно недостаток исходного макроса,-надо привести данные к виду ячеек ,где макрос сработал.