assembler x86-64

[DEADHUNT]

assembler x86-64 имеет возможность создавать 16, 32 и 64 битные программы. Выходной формат: двоичные или объектные COFF файлы. Ассемблер поддерживает простые и системные инструкции, инструкции математического сопроцессора, а также технологии: MMX, 3DNow!, SSE1, SSE2, SSE3, SSE4A, SSE4.1, SSE4.2. Имеет высокую скорость компиляции.
скачать

[ASSEMBLER]

Хм и как же сей продукт заставить 64 разрядные программы выдавать?

[DEADHUNT]

DDOS атака была, сейчас сайт работает.
чтобы создавать 64-битные программы есть типичное ключевое слово USE64

[DEADHUNT]

usage: asm [options] input output
options:
/BITS16 generate 16-bit code
/BITS32 generate 32-bit code
/BITS64 generate 64-bit code
/COFF generate COFF
/INC path add include path
/NOLOGO suppress startup banner
/HELP or /? display this message

[ASSEMBLER]

Что то я всё равно не пойму каким образом следует сегментацию указать, он не смотря ни на что безо всяких как ему кажется проблем выплёвывает мне файлы с непотребными заголовками

[DEADHUNT]

Сообщение от ASSEMBLER

Что то я всё равно не пойму каким образом следует сегментацию указать, он не смотря ни на что безо всяких как ему кажется проблем выплёвывает мне файлы с непотребными заголовками

приведи код, а то что-то не слишком понятно про какие ты сегменты. создание секций доступно только при создание *.OBJ (/COFF). синтаксис не как у MASM/TASM а такой же как в FASM/NASM

[ASSEMBLER]

Ну хотя бы вот этот, с насмовским синтаксисом:

SECTION .data 
msg: db "Hello World",0 

SECTION .text 
global _start 
_start: 
mov eax,3
mov ebx,2
add eax,ebx
ret

Можешь сам скинуть пример кода для 32 или 64 который адекватно компилируется

[DomiNick]

Может нужно:

"Hello World!$"

Хотя это в TASM, а других я не знаю...

[DEADHUNT]

Сообщение от ASSEMBLER

Ну хотя бы вот этот, с насмовским синтаксисом:

SECTION .data 
msg: db "Hello World",0 

SECTION .text 
global _start 
_start: 
mov eax,3
mov ebx,2
add eax,ebx
ret

Можешь сам скинуть пример кода для 32 или 64 который адекватно компилируется

public _start 
_start: 
mov eax,3
mov ebx,2
add eax,ebx
ret
msg: db "Hello World",0

или

codeseg
public _start 
_start: 
mov eax,3
mov ebx,2
add eax,ebx
ret
dataseg
msg: db "Hello World",0

многие директивы (org, public, extrn, times, dup, ....) имеют такой же синтаксис как в FASM. и как я понял это объектный файл то есть то есть ассемблер должен быть запущен с директивой /COFF

[DEADHUNT]

а теперь примеры

;
; feenv.asm
;
; Copyright (c) DevelSoftware. All right reserved.
;

; int __cdecl fegetenv(fenv_t * envp);
; int __cdecl feholdexcept(fenv_t * envp);
; int __cdecl fesetenv(const fenv_t * envp);
; int __cdecl feupdateenv(const fenv_t * envp);

public _fegetenv
public _feholdexcept
public _fesetenv
public _feupdateenv

_fegetenv:
ifdef _BITS64
	mov rax, [rsp + 8]
	fstenv [rax]
else
	mov eax, [esp + 4]
	fstenv [eax]
endif
	xor eax, eax
	ret
	
_feholdexcept:
ifdef _BITS64
	mov rax, [rsp + 8]
	fstenv [rax]
	fnclex
	sub rsp, 8
	fstcw [rsp]
	or byte [rsp], 0x3f
	fldcw [rsp]
	add rsp, 8
else
	mov eax, [esp + 4]
	fstenv [eax]
	fnclex
	sub esp, 4
	fstcw [esp]
	or byte [esp], 0x3f
	fldcw [esp]
	add esp, 4
endif
	xor eax, eax
	ret
	
_fesetenv:
ifdef _BITS64
	mov rax, [rsp + 8]
	fldenv [rax]
else
	mov eax, [esp + 4]
	fldenv [eax]
endif
	xor eax, eax
	ret
	
_feupdateenv:
	fstsw ax
	and ax, 0xff
ifdef _BITS64
	mov rax, [rsp + 8]
	mov [rax + 4], ax
	fldenv [rax]
else
	mov eax, [esp + 4]
	mov [eax + 4], ax
	fldenv [eax]
endif
	xor eax, eax
	ret

;
; _lldiv.asm
;
; Copyright (c) DevelSoftware. All right reserved.
;

public __lldiv

__lldiv:
	push ebx ; Save EBX as per calling convention.
	push esi ; Save ESI as per calling convention.
	push edi ; Save EDI as per calling convention.
	mov ecx, [esp+28] ; divisor_hi
	mov ebx, [esp+24] ; divisor_lo
	mov edx, [esp+20] ; dividend_hi
	mov eax, [esp+16] ; dividend_lo
	mov esi, ecx ; divisor_hi
	xor esi, edx ; divisor_hi ^ dividend_hi
	sar esi, 31 ; (quotient < 0) ? -1 : 0
	mov edi, edx ; dividend_hi
	sar edi, 31 ; (dividend < 0) ? -1 : 0
	xor eax, edi ; If (dividend < 0),
	xor edx, edi ; compute 1's complement of dividend.
	sub eax, edi ; If (dividend < 0),
	sbb edx, edi ; compute 2's complement of dividend.
	mov edi, ecx ; divisor_hi
	sar edi, 31 ; (divisor < 0) ? -1 : 0
	xor ebx, edi ; If (divisor < 0),
	xor ecx, edi ; compute 1's complement of divisor.
	sub ebx, edi ; If (divisor < 0),
	sbb ecx, edi ; compute 2's complement of divisor.
	jnz big_divisor ; divisor > 2^32 - 1
	cmp edx, ebx ; Only one division needed (ECX = 0)?
	jae two_divs ; Need two divisions.
	div ebx ; EAX = quotient_lo
	mov edx, ecx ; EDX = quotient_hi = 0 (quotient in EDX:EAX)
	xor eax, esi ; If (quotient < 0),
	xor edx, esi ; compute 1's complement of result.
	sub eax, esi ; If (quotient < 0),
	sbb edx, esi ; compute 2's complement of result.
	pop edi ; Restore EDI as per calling convention.
	pop esi ; Restore ESI as per calling convention.
	pop ebx ; Restore EBX as per calling convention.
	ret 16; Done, return to caller.
two_divs:
	mov ecx, eax ; Save dividend_lo in ECX.
	mov eax, edx ; Get dividend_hi.
	xor edx, edx ; Zero-extend it into EDX:EAX.
	div ebx ; quotient_hi in EAX
	xchg eax, ecx ; ECX = quotient_hi, EAX = dividend_lo
	div ebx ; EAX = quotient_lo
	mov edx, ecx ; EDX = quotient_hi (quotient in EDX:EAX)
	jmp make_sign ; Make quotient signed.
big_divisor:
	sub esp, 12 ; Create three local variables.
	mov [esp], eax ; dividend_lo
	mov [esp+4], ebx ; divisor_lo
	mov [esp+8], edx ; dividend_hi
	mov edi, ecx ; Save divisor_hi.
	shr edx, 1 ; Shift both
	rcr eax, 1 ; divisor and
	ror edi, 1 ; and dividend
	rcr ebx, 1 ; right by 1 bit.
	bsr ecx, ecx ; ECX = number of remaining shifts
	shrd ebx, edi, cl ; Scale down divisor and
	shrd eax, edx, cl ; dividend such that divisor is
	shr edx, cl ; less than 2^32 (that is, fits in EBX).
	rol edi, 1 ; Restore original divisor_hi.
	div ebx ; Compute quotient.
	mov ebx, [esp] ; dividend_lo
	mov ecx, eax ; Save quotient.
	imul edi, eax ; quotient * divisor high word (low only)
	mul dword [esp+4] ; quotient * divisor low word
	add edx, edi ; EDX:EAX = quotient * divisor
	sub ebx, eax ; dividend_lo - (quot.*divisor)_lo
	mov eax, ecx ; Get quotient.
	mov ecx, [esp+8] ; dividend_hi
	sbb ecx, edx ; Subtract (divisor * quot.) from dividend
	sbb eax, 0 ; Adjust quotient if remainder is negative.
	xor edx, edx ; Clear high word of quotient.
	add esp, 12 ; Remove local variables.
make_sign:
	xor eax, esi ; If (quotient < 0),
	xor edx, esi ; compute 1's complement of result.
	sub eax, esi ; If (quotient < 0),
	sbb edx, esi ; compute 2's complement of result.
	pop edi ; Restore EDI as per calling convention.
	pop esi ; Restore ESI as per calling convention.
	pop ebx ; Restore EBX as per calling convention.
	ret 16; Done, return to caller.