Сортировка по имени в Qbasic, программа внутри

[DAN1L]

Вот программа без сортировки: необходимо отсортировать по имени магазина в алфавитном порядке

CLS
TYPE mag
   mname AS STRING * 12
   street AS STRING * 10
   homenum AS INTEGER
   phonenum AS LONG
   tip AS STRING * 12
END TYPE
DIM shop(1 TO 10) AS mag
DIM i AS INTEGER
DATA sportmaster, lenina, 17, 7559087, sportmag
DATA autolite, frunze, 88, 7507590, automag
DATA bestbook, gagarina, 27, 7102535, bookmag
DATA hotbread, lomonosova, 152, 7506170, bulochnaya
DATA okay, voennaya, 6, 7201515, gastronom
DATA mega, vatutina, 105, 7105065,univermag
DATA ovoshi, visockogo, 32, 7802878, ovoshmag
DATA autolider, lenina, 29, 7201625, automag
DATA ashan, vatutina, 103, 7205028, gastronom
DATA intersport, gogolya, 98, 7252054, sportmag
FOR i = 1 TO 10
   READ shop(i).mname, shop(i).street, shop(i).homenum, shop(i).phonenum, shop(i).tip
   PRINT shop(i).mname, shop(i).street, shop(i).homenum, shop(i).phonenum, shop(i).tip
NEXT i
END

Вот что в итоге



___________
Код нужно оформлять по правилам:
тегом [CODE]..[/СODE] (это кнопочка с решёточкой #)
Не забывайте об этом!
Модератор.

[DAN1L]

вот сделал, но он сортирует только 1й столбец, а остальные записи остаются без изменения. Как сделать что бы строкой переносилось?

TYPE mag
   mname AS STRING * 12
   street AS STRING * 12
   homenum AS INTEGER
   phonenum AS LONG
   tip AS STRING * 15
END TYPE
DIM shop(1 TO 10) AS mag
DIM i, j, n AS INTEGER
DIM m AS STRING
CLS
DATA SPORTMASTER, Lenina, 17, 7559087, sportmag
DATA AUTOLIFE, Frunze, 88, 7507598, automag
DATA BESTBOOK, Gagarina, 27, 7102535, bookmag
DATA HOTBREAD, Lomonosova, 152, 7506170, bulochnaya
DATA OKAY, Voennaya, 6, 7201515, gastronom
DATA MEGA, Vatutina, 105, 7105065, universam
DATA OVOSHI, Visockogo, 32, 7802878, ovoshmag
DATA AUTOLIDER, Lenina, 29, 7201625, automag
DATA ASHAN, Vatutina, 103, 7205028, gastronom
DATA INTERSPORT, Gogolya, 98, 7252054, sportmag
FOR i = 1 TO 10
   READ shop(i).mname, shop(i).street, shop(i).homenum, shop(i).phonenum, shop(i).tip
   PRINT shop(i).mname, shop(i).street, shop(i).homenum, shop(i).phonenum, shop(i).tip
NEXT i
FOR i = 1 TO 9
   m = shop(i).mname
   n = i
   FOR j = i + 1 TO 10
      IF shop(j).mname < m THEN
         m = shop(j).mname
         n = j
      END IF
   NEXT j
   shop(n).mname = shop(i).mname
   shop(i).mname = m
NEXT i
PRINT "otsortirovanniy massiv"
FOR i = 1 TO 10
   PRINT shop(i).mname, shop(i).street, shop(i).homenum, shop(i).phonenum, shop(i).tip
NEXT i
END

[Serge_Bliznykov]

так пойдёт?

TYPE mag
   mname AS STRING * 12
   street AS STRING * 12
   homenum AS INTEGER
   phonenum AS LONG
   tip AS STRING * 15
END TYPE
DIM shop(1 TO 10) AS mag
DIM OneShop AS mag
DIM i, j AS INTEGER
CLS
DATA SPORTMASTER, Lenina, 17, 7559087, sportmag
DATA AUTOLIFE, Frunze, 88, 7507598, automag
DATA BESTBOOK, Gagarina, 27, 7102535, bookmag
DATA HOTBREAD, Lomonosova, 152, 7506170, bulochnaya
DATA OKAY, Voennaya, 6, 7201515, gastronom
DATA MEGA, Vatutina, 105, 7105065, universam
DATA OVOSHI, Visockogo, 32, 7802878, ovoshmag
DATA AUTOLIDER, Lenina, 29, 7201625, automag
DATA ASHAN, Vatutina, 103, 7205028, gastronom
DATA INTERSPORT, Gogolya, 98, 7252054, sportmag
FOR i = 1 TO 10
   READ shop(i).mname, shop(i).street, shop(i).homenum, shop(i).phonenum, shop(i).tip
   PRINT shop(i).mname, shop(i).street, shop(i).homenum, shop(i).phonenum, shop(i).tip
NEXT i

REM Сортировка массива shop
FOR i = 1 TO 9
  FOR j = i + 1 TO 10
    IF shop(i).mname > shop(j).mname THEN
          OneShop = shop(i)
          shop(i) = shop(j)
          shop(j) = OneShop
    END IF
 NEXT j
NEXT i
PRINT
PRINT "otsortirovanniy massiv"
FOR i = 1 TO 10
   PRINT shop(i).mname, shop(i).street, shop(i).homenum, shop(i).phonenum, shop(i).tip
NEXT i
END

[DAN1L]

Все отлично работает! Спасибо вам!) Блин сколько же я над ней сидел

[DAN1L]

Сообщение от Serge_Bliznykov

так пойдёт?

Вы случайно не знаете как "методом пузырька" записывается сортировка в этой же задаче?

[Serge_Bliznykov]

а в чём, собственно, сложность?

не знаете, что такое "метод пузырькаЭ ?!

с википедии

Сортировка простыми обменами, сортиро́вка пузырько́м (англ. bubble sort) — простой алгоритм сортировки.

или не можете алгоритм на бейсике записать?
вот, с оттуда же на псевдокоде:

Вход: массив A, состоящий из N элементов, с нумерацией от A[1] до A[N]

t := истина
цикл пока t истинно:
  t := ложь
  цикл для j = 1, 2, ..., n − 1:
    если A[j] > A[j+1], то:
      обменять местами элементы A[j] и A[j+1]
      t := истина

[DAN1L]

Спасибо!) Буду пробовать, не особо я силен в программирование