Количество книг в папке

[Palomnik1096]

Добрый день.
Названия книг в папке имеют название Customer1,Customer2 ... и т.д. , общее количество не известно, но название начинается с одного и того жеCustomer, как определить сколько таких книг в папке, я смог написать процедуру, которая позволяет открывать эти книги, переименовывать и сохранять с новым именем, но это можно делать только точно зная их количество (с помощью For next), а как сделать так, чтобы процедура выполнялась, при условии что количество таких книг не известно.

For i = 1 To 4
Workbooks.Open Filename:="C:\Documents and Settings\" _
& "Александр\Рабочий стол\Покупатели\Customer" & i
With ActiveWorkbook
.SaveAs Filename:="C:\Documents and Settings\" _
& "Александр\Рабочий стол\Покупатели\CostOders" & i
MsgBox "Имя этой книги " & ActiveWorkbook.Name & "" _
& " книга создана " & Date & " в " & Time & "."
.Close
End With
Next i

[kuklp]

Как-то так:

Public Sub www()
    Dim MyName$, i&
    MyName = Dir("C:\Documents and Settings\Александр\Рабочий стол\Покупатели\Customer*.*")
    Do While MyName <> ""
        i = i + 1
            Workbooks.Open Filename:=MyName
            With ActiveWorkbook
                .SaveAs Filename:="C:\Documents and Settings\" _
                                & "Александр\Рабочий стол\Покупатели\CostOders" & i 
                MsgBox "Имя этой книги " & ActiveWorkbook.Name & "" _
                     & " книга создана " & Date & " в " & Time & "."
                .Close
            End With
        MyName = Dir
    Loop
End Sub

[Palomnik1096]

Идея понятна, но только в этом месте дает ошибку, о том либо путь указан не верно, либо файл отсутствует!

Workbooks.Open Filename:=MyName

[kuklp]

Ну раз понятна идея, кто мешает посмотреть в окне Locals, что содержится в переменной MyName. К ней спереди полный путь приклеить надо. У меня же нет Вашей структуры каталогов и тем более Ваших файлов. Писал не проверяя.
Попробуйте:

Public Sub www()
    Dim MyName$, i&, mp$
    mp = "C:\Documents and Settings\Александр\Рабочий стол\Покупатели\"
    MyName = Dir(mp & "Customer*.*")
    Do While MyName <> ""
        i = i + 1
            Workbooks.Open Filename:=mp & MyName
            With ActiveWorkbook
                .SaveAs Filename:=mp & "CostOders" & i
                MsgBox "Имя этой книги " & ActiveWorkbook.Name & "" _
                     & " книга создана " & Date & " в " & Time & "."
                .Close
            End With
        MyName = Dir
    Loop
End Sub

[Palomnik1096]

ОГРОМНОЕ СПАСИБО!!!

Едиственный вопрос по строкам:

Dim MyName$, i&, mp$, здесь понятно, что объявляется переменная MyName, а что означает $,i&, mp$?
И строка MyName = Dir, а смысл ее какой?

[kuklp]

$ - строковый тип
& - long
По-поводу Dir почитайте справку.

[IgorGO]

Сергей, правильно писать:
"По-поводу Dir почитайте справку, пожалуйста."))

[kuklp]

Сообщение от IgorGO

Сергей, правильно писать:
"По-поводу Dir почитайте справку, пожалуйста."))

Привет, Игорь. Впредь буду знать Вопрос - это только по-поводу Dir или взагали?

[SAS888]

А зачем открывать каждый файл только для того, чтобы сохранить его под другим именем? Почему нельзя просто переименовать?

Sub Main()
    Dim MyPath As String, MyName As String, i As Long: i = 1
    MyPath = "C:\Documents and Settings\Александр\Рабочий стол\Покупатели\"
    MyName = Dir(MyPath & "Customer*")
    Do While MyName <> ""
        Name MyPath & MyName As MyPath & "CostOders" & i
        i = i + 1: MyName = Dir
    Loop
End Sub

[kuklp]

Сообщение от SAS888

А зачем открывать каждый файл только для того, чтобы сохранить его под другим именем? Почему нельзя просто переименовать?

Sub Main()
    Dim MyPath As String, MyName As String, i As Long: i = 1
    MyPath = "C:\Documents and Settings\Александр\Рабочий стол\Покупатели\"
    MyName = Dir(MyPath & "Customer*")
    Do While MyName <> ""
        Name MyPath & MyName As MyPath & "CostOders" & i
        i = i + 1: MyName = Dir
    Loop
End Sub

И то верно. Ну, пути ТС неисповедимы...