выделение листов по условию

[Bronyk]

здравствуйте помогите пожалуйста нужно реализовать небольшой програмный кодик!!
вообщем есть документ с кучей листов (а точнее их около 50) так вот надо сделать так что бы листы выделялись если в ячейке x25 на этом же листе значение не равно Ноль
If Worksheets("1").Range("x25") > 0 Then Sheets("1").Select
тоесть нужно выделить несколько листов с помошью Sheets(Array("1","2",.....,"50",)). Select

обьясните пожалуйста как это сделать

[SAS888]

Например, так:

Sub SelectSheets()

    Dim a() As Integer, i As Integer, j As Integer
    
    ReDim a(1 To Sheets.Count) 'Определяем максимально возможную размерность массива
    j = 0 ' Указатель формируемого массива
    
    For i = 1 To Sheets.Count ' Цикл по всем листам
        If Sheets(i).Range("X25") <> 0 Then ' Проверка Вашего условия
            j = j + 1 ' Инкремент указателя
            a(j) = Sheets(i).Index ' Формируем массив
        End If
    Next
    
    ReDim Preserve a(1 To j) ' Переопределяем размерность полученного массива
    Sheets(a).Select ' Условное выделение нужных листов

End Sub

[Bronyk]

Спасибо большое а еще подскажите пожалуйста как можно задать относительный путь !
у меня есть файлик в котором есть кнопочка при нажатии на которую раскрывается файлик с названием итоги мне надо чтобы они лежат в одной папке
ну и если не тяжело то как его после открытия сразу закрыть с сохранениями ! !

[SAS888]

Не совсем понял вопрос. Что значит

относительный путь

Если, например, нужно сохранить открытый файл "Книга2" в папку, в которой находится файл с выполняемым макросом, то можно так:

Windows("Книга2").Activate
    ActiveWorkbook.SaveCopyAs ThisWorkbook.Path & "\" & ActiveWorkbook.Name & ".xls"

Важно помнить, что "ActiveWorkbook" - это рабочая книга, которая в данный момент активна, а "ThisWorkbook" - это рабочая книга, содержащая исполняемый код.
Сохранить и закрыть активную рабочую книгу в ту же директорию, из которой она открыта, и с тем же именем (т.е. последовательно выполнить команды "Сохранить" и "Закрыть"), можно так:

ActiveWorkbook.Close savechanges:=True

[Bronyk]

по поводу относительного пути !! допустим надо отрыть файл из той же папки в которой лежит главный файлик!! т.е есть два файла первый главный в нем есть кнопка которая по нажатии на нее открывает фалик итоги который лежит в тойже папке где и главный(там прописан весь путь)!! но на разных компьютерах разные директории

[Bronyk]

извените за беспокойство уже все нашел на вашем форуме Спасибо большое!!