Открытие файлов из заданной папки

[anutiks]

Помогите, плиз! В определенной папке есть файлы Exel, нужно чтобы макрос автоматом открывал их по очереди и редактировал. Как такое можно сделать?

[SAS888]

Можно использовать метод "FileSearch", но в Excel 2007 он работать не будет. Поэтому, предлагаю сделать так:

Sub ManyFiles()

    Dim Directory As String, f As String
    Directory = "D:\Temp\" ' Путь к исходной папке
    f = Dir(Directory, 7) 'Получение первого файла
    Do While f <> ""
        Workbooks.Open Filename:=Directory & f
            'Здесь расположите код, который необходимо выполнить
            ' для каждого файла   
        ActiveWorkbooks.Save
        ActiveWorkbooks.Close
        
        f = Dir 'Получение следующего файла
    Loop
    
End Sub

Если нужно, предварительно задать путь (выбрать папку), то для этого в начале процедуры можно вызвать соответствующее стандартное диалоговое окно Excel.

[дмидми]

Пожалуй, имеет смысл перебирать только файлы с определённым расширением, исключив к тому же из рассмотрения файлы с ненужными атрибутами (вроде ReadOnly, Hidden и System, которые зачем-то подключил уважаемый SAS888), но не забыв подключить файлы с атрибутами допустимыми.

Рассчитывать на то, что к моменту окончания обработки очередная книга будет оставаться активной, я бы не советовал.

Sub DirFunctionExample()
    Const myPattern = "*.XLS"
    Dim myPath As String, myName As String, Wb As Workbook

    myPath = CurDir & Application.PathSeparator
    myName = Dir(myPath & myPattern, vbNormal + vbArchive)
    Do While myName <> ""
        Set Wb = Workbooks.Open(Filename:=myPath & myName _
            , AddToMRU:=False)
        '
        '...
        '
        Wb.Save
        Wb.Close
        myName = Dir   ' Get next entry.
    Loop
End Sub

P.S. Подробности: поставить в VBA курсор на Dir и нажать F1

[SAS888]

Согласен полностью.

[anutiks]

Ух-ты как все подробно по полочкам разложили!!! Спасибо, пойду пробовать.

[anutiks]

И еще вопросик. Как потом отредактированный файл сохранить под этим же именем только в другой каталог?

[SAS888]

Вместо

Wb.Save

используй

Wb.SaveAs Filename:="D:\Temp\" & myName

, где "D:\Temp\" - это новый путь. И далее, если нужно, параметры сохранения (FileFormat, Password, ReadOnly и т.п). Смотри help по VBA.

[anutiks]

Спасибки!