Как удалить из ячейки слово, содержащее....

[Solny]

Добрый день!
Подскажите, пожалуйста, как можно удалить из ячейки слово, содержащее определенные символы.
Проблема следующая: наименования в прайсе содержат артикулы, которые необходимо удалить.
Например: "Самокл.этикетки AZ9184-25 ECONOMY,универ,38x21,2мм,белые,25л" .
Нужно удалить "AZ9184-25".
Все артикулы содержат впереди символы "AZ"

[Hugo121]

Sub tt()
    Dim s$, a, i&
    s = [a1].Value
    a = Split(s)
    For i = 0 To UBound(a)
        If a(i) Like "AZ#*" Then a(i) = ""
    Next
    s = Application.Trim(Join(a))
    [b1].Value = s
End Sub

Ваш текст в A1.

Можно чуть сократить:

Sub ttt()
    Dim a, i&: a = Split([a1].Value)
    For i = 0 To UBound(a)
        If a(i) Like "AZ#*" Then a(i) = ""
    Next: [b1].Value = Application.Trim(Join(a))
End Sub

или так:

Sub tttt(): Dim a, i&: a = Split([a1].Value)
For i = 0 To UBound(a): a(i) = IIf(a(i) Like "AZ#*", "", a(i)): Next
[b1].Value = Application.Trim(Join(a)): End Sub

[Solny]

Спасибо!
Навесила цикл сверху, все работает!

[Hugo121]

Да, ещё можно Exit For добавить, когда нашли совпадение (если артикул всегда один) - будет быстрее работать. Если данных много - будет заметно.
Но если их много и обрабатывать нужно часто - берите сперва в массив, обрабатывайте, выгружайте назад.

[Solny]

Спасибо за помощь!
Проблема в том, что я совсем новичок)))))
Еще попутно возникла проблема с другим файлом, там нужно удалить
последние цифры в строке, примеры:
Боковая крышка д/рельса Junior, пластиковая 11 115 36
Мелки цветные,12 мелков 6 цветов в картонной коробке 12306
Настол. одност. подставка Magnetoplan, А3, 297х105х420мм 43105
Доска белая Magnetoplan CC,600х450мм,эмал.покрытие,магн/марк 12 402 СС

Хотела просто формулой типа:
=ЛЕВСИМВ(RC[-1];ДЛСТР(RC[-1])-9)
но проблема, что количество знаков разное......
а в макросах не сильна совсем

Помогите, пожалуйста, если не сложно
Буду очень благодарна

[IgorGO]

удачный пример сразу видно несколько проблем:
Боковая крышка д/рельса Junior, пластиковая 11 115 36
тут что удалаять 36 или 11 115 36?

Доска белая Magnetoplan CC,600х450мм,эмал.покрытие,магн/марк 12 402 СС
тут что удалять? 1)ничего 2)12 402 СС 3)12 402 а СС оставить????

[Solny]

Нда, неудачно написала...
Удалять соответственно:
11 115 36
12306
43105
12 402 СС

[nerv]

\из той же оперы. Hugo121, и все-таки я люблю For Each Variant In Array : )

Sub io()
Dim v, x As String
For Each v In Split([A1].Value)
    If Not v Like "AZ#*" Then x = x & " " & v
Next
x = LTrim(x)
End Sub

[Solny]

Всем спасибо большое!

Оба файла обработала!

Кстати, последний код не работал для строк с СС на конце, их формулой добила.

[TheVinnie]

Для ценителей универсальности подойдет вещь на базе regex

Sub AutoReplaceArticles()

On Error Resume Next

For Each x In Selection
      
    If WorksheetFunction.IsNA(x) Then
           x.Value = ""
    Else
        
        Dim s$
        s = x.Value
        
        Dim regEx
        Set regEx = CreateObject("vbscript.regexp")
        With regEx
            .IgnoreCase = True
            .MultiLine = False
            .Pattern = "\s+[ |0-9A-Za-z]+$"
            .Global = True
        End With

        x.Value = regEx.Replace(s, "")
    End If
              
    Next
    
End Sub