Размер файла

[Garmon]

Работаем на 16 разрядных машинах,под досом.Люди помогите пожалуйста.В дз нужно узнать размер файла.Подскажите какая функция и прерывание это обеспечивает.

[Mikl___]

Garmon
Размер какого файла? 1) Произвольного или чтобы 2) ЕХЕ/СОМ-файл определял свой размер?
1) Если произвольного

MOV AX,3D00h
MOV DX,OFFSET FILENAME
INT 21h ;открыть файл для чтения
MOV BX,AX
MOV AX,4202h
XOR CX,CX ;определяем длину файла для чего
XOR DX,DX ;позиционируемся в конец файла
INT 21h
MOV FILELENTH,AX

2) Если СОМ файл, то при открытии в СХ содержится длина файла в байтах
3) если ЕХЕ, то вот код, который позволяет вывести размер текущей программы в байтах

; masm dos exe #
.286
.model small
.code
start:	mov ax,ds:[2Сh]; здесь лежит адрес сегмента окружения
	mov ds,ax
	xor ax,ax
	cwd; dx=0
	mov si,ax
@@:	lodsw; ищем два нуля
	dec si
	test ax,ax
	jnz @b
	add si,3; перешагнем через 00,00,01,00
	mov dx,si;передаем в DX адрес с именем запущенной программы
	mov ah,3Dh;открываем файл на чтение
	int 21h
	xchg bx,ax
	xor cx,cx
	mov ax,4202h;получаем длину файла
	int 21h
        push ax
	mov ah,3eh;закрываем файл
	int 21h
        pop ax; длина файла в DX:AX
	xchg dx,ax
	push cs
	pop ds
	mov bx,offset x_table
	call PrintWord; Hex->ASCII
	xchg dx,ax
	call PrintWord; Hex->ASCII
	mov dx,offset mes; сообщение на экран
	mov ah,9
	int 21h
	mov ah,0;ждем нажатия на клавиатуру
	int 16h
	mov ah,4Ch;выходим из программы
	int 21h
PrintWord PROC
	push ax
	xchg ah,al
	call @f
	pop ax
@@: push ax;PrintByte
	shr al,4
	xlat
	int 29h
	pop ax
	and al,0Fh
	xlat
	int 29h
	retn
PrintWord ENDP
x_table db '0123456789ABCDEF'
mes     db ' - program length$'
end start

[Mikl___]

более удачный 3-ий вариант

; masm dos exe #
.286
;Вывести размер текущей программы в байтах
.model small
.code
start:	mov ax,ds:[2Ch]; здесь лежит адрес сегмента окружения
	mov es,ax
	mov ds,ax
	xor ax,ax	
	mov di,ax
	or cx,-1
@@:	repne scasb; ищем два нуля
	scasb
	jnz @b
	lea dx,[di+2]; имя запущенной программы
	mov ah,3Dh 
	int 21h;открыли файл на чтение
	xchg bx,ax ; в ВХ файловый указатель, в АХ ноль 
	cwd            ;dx:=0
	xor cx,cx	
	mov ax,4202h
	int 21h; в AX длина программы
	mov cx,10; основание системы счисления
	call @f         ;число в строку
	mov ah,3Eh
	int 21h  ;закрыли файл
	push cs
	pop ds   ; ds:=cs
	mov dx,offset mes
	mov ah,9
	int 21h; вывели сообщение на экран
	mov ah,0
	int 16h; ждем нажатия на клавиатуру
	mov ah,4Ch
	int 21h; выходим из программы
@@:     xor dx,dx
        div cx
        push dx      ; запомнить остаток от деления
        or ax,ax ; частное == 0 ?
        jz @f
        call @b     ; рекурсивный вызов (если есть что делить)
@@:	pop ax
        add al,'0'
        int 29h              ; вывод символа 
        retn
mes     db ' - длина программы$'
end start