Проверка надежности пароля

[ru3000]

Облазил все форумы по Excel, VB, cmd и пр. - ну нигде не нашел даже намека на возможность вероятности хотя бы приблизительного, хотя бы отдаленного решения одной, ну уж совсем казалось бы примитивной (?), задачи. Или быть может это настолько примитивная задача, что люди даже и не берутся об нее пачкаться? Все что смог найти - все относиться только к веб-программированию. Но оно мене не надо!
А нужно-то всего ничего - создать одну несчастную форму с одной несчастной обработкой. Чтобы пользователь вписал в предложенную форму придуманный им пароль, нажал кнопку OK, а форма ответила бы ему - отвечает его пароль требованиям безопасности или нет.
Ну разве я многого требую? А?

[ru3000]

Ура! Нашел! http://msdn.microsoft.com/ru-ru/library/b05h65z0.aspx
Только теперь осталось воткнуть это все в мой excel.

[Казанский]

Просто у каждого свое понимание, что такое хороший пароль
Учтите, что работа с регулярными выражениями в VBA организуется совершенно по-другому. Поcмотрите например
http://www.script-coding.com/WSH/RegExp.html

[doober]

Сообщение от ru3000

Ура! Нашел! http://msdn.microsoft.com/ru-ru/library/b05h65z0.aspx
Только теперь осталось воткнуть это все в мой excel.

Вот так

Function ValidatePassword(ByVal pwd As String, Optional ByVal minLength As Integer = 8, _
                          Optional ByVal numUpper As Integer = 2, _
                          Optional ByVal numLower As Integer = 2, _
                          Optional ByVal numNumbers As Integer = 2, _
                          Optional ByVal numSpecial As Integer = 2) As Boolean
        Set RegExp = CreateObject("VBScript.RegExp")
        ' Replace [A-Z] with \p{Lu}, to allow for Unicode uppercase letters.
        Dim upper, lower, number, special
        RegExp.Pattern = "[A-Z]"
        Set upper = RegExp.Execute(pwd)
        RegExp.Pattern = "[a-z]"
        Set lower = RegExp.Execute(pwd)
        RegExp.Pattern = "[0-9]"
        Set number = RegExp.Execute(pwd)
        RegExp.Pattern = "[^a-zA-Z0-9]"
        Set special = RegExp.Execute(pwd)

        ' Check the length.
        If Len(pwd) < minLength Then ValidatePassword False: Exit Function
        ' Check for minimum number of occurrences.
        If upper.Count < numUpper Then ValidatePassword = False: Exit Function
        If lower.Count < numLower Then ValidatePassword = False: Exit Function
        If number.Count < numNumbers Then ValidatePassword = False: Exit Function
        If special.Count < numSpecial Then ValidatePassword = False: Exit Function

        ' Passed all checks.
        ValidatePassword = True
End Function

Sub TestValidatePassword()
     password = "Password"
    ' Demonstrate that "Password" is not complex.
    MsgBox (password & " is complex: " & ValidatePassword(password))

    password = "Z9f%a>2kQ"
    ' Demonstrate that "Z9f%a>2kQ" is not complex.
    MsgBox (password & " is complex: " & ValidatePassword(password))
End Sub

[EducatedFool]

Тут делов-то... на 3-10 строк кода:
1) проверить длину пароля функцией Len()
2) проверить на наличие спецсимволов, цифр, русских и английских букв функцией Like или Instr
3) исходя из результатов проверки, вывести сообщение о допустимости (или недопустимости) пароля

[Казанский]

doober, забыл

RegExp.Global = True

Без этого Count никогда не будет >1

[Казанский]

В общем, если выкинуть все лишнее, получится так:

Function ValidatePassword(ByVal pwd As String, Optional ByVal minLength As Integer = 8, _
                          Optional ByVal numUpper As Integer = 2, _
                          Optional ByVal numLower As Integer = 2, _
                          Optional ByVal numNumbers As Integer = 2, _
                          Optional ByVal numSpecial As Integer = 2) As Boolean
If Len(pwd) < minLength Then Exit Function
With CreateObject("VBScript.RegExp")
    .Global = True
    .Pattern = "[A-Z]"
    If .Execute(pwd).Count < numUpper Then Exit Function
    .Pattern = "[a-z]"
    If .Execute(pwd).Count < numLower Then Exit Function
    .Pattern = "[0-9]"
    If .Execute(pwd).Count < numNumbers Then Exit Function
    .Pattern = "[^a-zA-Z0-9]"
    ValidatePassword = .Execute(pwd).Count >= numSpecial
End With
End Function

[ru3000]

Казанский, doober, EducatedFool, спасибо большое, что откликнулись.
Но у меня никак не получается привязать код к моей форме. Уже все пальцы на руках перепутались - ну ни как не сообразить мне какую строчку/скобку/закавычку куда поставить, чтобы этот (разкудрить его в коромысло) код начал делать то, чего от него требуется.
Гляньте, пожааалуйста, чо я там натворил.

[doober]

Сообщение от Казанский

doober, забыл

RegExp.Global = True

Без этого Count никогда не будет >1

Это точно,забыл.Мне ближе код-оригинал.

[doober]

Сообщение от ru3000

код начал делать то, чего от него требуется.
Гляньте, пожааалуйста, чо я там натворил.

Странно,он там ничего не делает.
Если правильноный пароль,то и сообщение соответствующее

---------------------------------------------------------------